arch/x86/cpu/start.S

   1 /*
   2  *  U-Boot - x86 Startup Code
   3  *
   4  * (C) Copyright 2008-2011
   5  * Graeme Russ, <graeme.russ@gmail.com>
   6  *
   7  * (C) Copyright 2002
   8  * Daniel Engström, Omicron Ceti AB, <daniel@omicron.se>
   9  *
  10  * SPDX-License-Identifier:     GPL-2.0+
  11  */
  12
  13 #include <config.h>
  14 #include <asm/global_data.h>
  15 #include <asm/post.h>
  16 #include <asm/processor.h>
  17 #include <asm/processor-flags.h>
  18 #include <generated/generic-asm-offsets.h>
  19 #include <generated/asm-offsets.h>
  20
  21 .section .text
  22 .code32
  23 .globl _start
  24 .type _start, @function
  25 .globl _x86boot_start
  26 _x86boot_start:
  27         /*
  28          * This is the fail safe 32-bit bootstrap entry point. The
  29          * following code is not executed from a cold-reset (actually, a
  30          * lot of it is, but from real-mode after cold reset. It is
  31          * repeated here to put the board into a state as close to cold
  32          * reset as necessary)
  33          */
  34         cli
  35         cld
  36
  37         /* Turn off cache (this might require a 486-class CPU) */
  38         movl    %cr0, %eax
  39         orl     $(X86_CR0_NW | X86_CR0_CD), %eax
  40         movl    %eax, %cr0
  41         wbinvd
  42
  43         /* Tell 32-bit code it is being entered from an in-RAM copy */
  44         movw    $GD_FLG_WARM_BOOT, %bx
  45         jmp     1f
  46 _start:
  47         /*
  48          * This is the 32-bit cold-reset entry point. Initialize %bx to 0
  49          * in case we're preceeded by some sort of boot stub.
  50          */
  51         movw    $GD_FLG_COLD_BOOT, %bx
  52 1:
  53         /* Save BIST */
  54         movl    %eax, %ebp
  55
  56         /* Load the segement registes to match the gdt loaded in start16.S */
  57         movl    $(X86_GDT_ENTRY_32BIT_DS * X86_GDT_ENTRY_SIZE), %eax
  58         movw    %ax, %fs
  59         movw    %ax, %ds
  60         movw    %ax, %gs
  61         movw    %ax, %es
  62         movw    %ax, %ss
  63
  64         /* Clear the interrupt vectors */
  65         lidt    blank_idt_ptr
  66
  67         /* Early platform init (setup gpio, etc ) */
  68         jmp     early_board_init
  69 .globl early_board_init_ret
  70 early_board_init_ret:
  71         post_code(POST_START)
  72
  73         /* Initialise Cache-As-RAM */
  74         jmp     car_init
  75 .globl car_init_ret
  76 car_init_ret:
  77 #ifndef CONFIG_HAVE_FSP
  78         /*
  79          * We now have CONFIG_SYS_CAR_SIZE bytes of Cache-As-RAM (or SRAM,
  80          * or fully initialised SDRAM - we really don't care which)
  81          * starting at CONFIG_SYS_CAR_ADDR to be used as a temporary stack
  82          * and early malloc area. The MRC requires some space at the top.
  83          *
  84          * Stack grows down from top of CAR. We have:
  85          *
  86          * top-> CONFIG_SYS_CAR_ADDR + CONFIG_SYS_CAR_SIZE
  87          *      MRC area
  88          *      global_data
  89          *      x86 global descriptor table
  90          *      early malloc area
  91          *      stack
  92          * bottom-> CONFIG_SYS_CAR_ADDR
  93          */
  94         movl    $(CONFIG_SYS_CAR_ADDR + CONFIG_SYS_CAR_SIZE - 4), %esp
  95 #ifdef CONFIG_DCACHE_RAM_MRC_VAR_SIZE
  96         subl    $CONFIG_DCACHE_RAM_MRC_VAR_SIZE, %esp
  97 #endif
  98 #else
  99         /*
 100          * When we get here after car_init, esp points to a temporary stack
 101          * and esi holds the HOB list address returned by the FSP.
 102          */
 103 #endif
 104
 105         /* Reserve space on stack for global data */
 106         subl    $GENERATED_GBL_DATA_SIZE, %esp
 107
 108         /* Align global data to 16-byte boundary */
 109         andl    $0xfffffff0, %esp
 110         post_code(POST_START_STACK)
 111
 112         /* Zero the global data since it won't happen later */
 113         xorl    %eax, %eax
 114         movl    $GENERATED_GBL_DATA_SIZE, %ecx
 115         movl    %esp, %edi
 116         rep     stosb
 117
 118 #ifdef CONFIG_HAVE_FSP
 119         test    %esi, %esi
 120         jz      skip_hob
 121
 122         /* Store HOB list */
 123         movl    %esp, %edx
 124         addl    $GD_HOB_LIST, %edx
 125         movl    %esi, (%edx)
 126
 127 skip_hob:
 128 #endif
 129         /* Setup first parameter to setup_gdt, pointer to global_data */
 130         movl    %esp, %eax
 131
 132         /* Reserve space for global descriptor table */
 133         subl    $X86_GDT_SIZE, %esp
 134
 135         /* Align temporary global descriptor table to 16-byte boundary */
 136         andl    $0xfffffff0, %esp
 137         movl    %esp, %ecx
 138
 139 #if defined(CONFIG_SYS_MALLOC_F_LEN)
 140         subl    $CONFIG_SYS_MALLOC_F_LEN, %esp
 141         movl    %eax, %edx
 142         addl    $GD_MALLOC_BASE, %edx
 143         movl    %esp, (%edx)
 144 #endif
 145         /* Store BIST */
 146         movl    %eax, %edx
 147         addl    $GD_BIST, %edx
 148         movl    %ebp, (%edx)
 149
 150         /* Set second parameter to setup_gdt */
 151         movl    %ecx, %edx
 152
 153         /* Setup global descriptor table so gd->xyz works */
 154         call    setup_gdt
 155
 156         /* Set parameter to board_init_f() to boot flags */
 157         post_code(POST_START_DONE)
 158         xorl    %eax, %eax
 159
 160         /* Enter, U-boot! */
 161         call    board_init_f
 162
 163         /* indicate (lack of) progress */
 164         movw    $0x85, %ax
 165         jmp     die
 166
 167 .globl board_init_f_r_trampoline
 168 .type board_init_f_r_trampoline, @function
 169 board_init_f_r_trampoline:
 170         /*
 171          * SDRAM has been initialised, U-Boot code has been copied into
 172          * RAM, BSS has been cleared and relocation adjustments have been
 173          * made. It is now time to jump into the in-RAM copy of U-Boot
 174          *
 175          * %eax = Address of top of new stack
 176          */
 177
 178         /* Stack grows down from top of SDRAM */
 179         movl    %eax, %esp
 180
 181         /* Reserve space on stack for global data */
 182         subl    $GENERATED_GBL_DATA_SIZE, %esp
 183
 184         /* Align global data to 16-byte boundary */
 185         andl    $0xfffffff0, %esp
 186
 187         /* Setup first parameter to memcpy (and setup_gdt) */
 188         movl    %esp, %eax
 189
 190         /* Setup second parameter to memcpy */
 191         fs movl 0, %edx
 192
 193         /* Set third parameter to memcpy */
 194         movl    $GENERATED_GBL_DATA_SIZE, %ecx
 195
 196         /* Copy global data from CAR to SDRAM stack */
 197         call    memcpy
 198
 199         /* Reserve space for global descriptor table */
 200         subl    $X86_GDT_SIZE, %esp
 201
 202         /* Align global descriptor table to 16-byte boundary */
 203         andl    $0xfffffff0, %esp
 204
 205         /* Set second parameter to setup_gdt */
 206         movl    %esp, %edx
 207
 208         /* Setup global descriptor table so gd->xyz works */
 209         call    setup_gdt
 210
 211         /* Set if we need to disable CAR */
 212 .weak   car_uninit
 213         movl    $car_uninit, %eax
 214         cmpl    $0, %eax
 215         jz      1f
 216
 217         call    car_uninit
 218 1:
 219         /* Re-enter U-Boot by calling board_init_f_r */
 220         call    board_init_f_r
 221
 222 die:
 223         hlt
 224         jmp     die
 225         hlt
 226
 227 blank_idt_ptr:
 228         .word   0               /* limit */
 229         .long   0               /* base */
 230
 231         .p2align        2       /* force 4-byte alignment */
 232
 233 multiboot_header:
 234         /* magic */
 235         .long   0x1BADB002
 236         /* flags */
 237         .long   (1 << 16)
 238         /* checksum */
 239         .long   -0x1BADB002 - (1 << 16)
 240         /* header addr */
 241         .long   multiboot_header - _x86boot_start + CONFIG_SYS_TEXT_BASE
 242         /* load addr */
 243         .long   CONFIG_SYS_TEXT_BASE
 244         /* load end addr */
 245         .long   0
 246         /* bss end addr */
 247         .long   0
 248         /* entry addr */
 249         .long   CONFIG_SYS_TEXT_BASE