arch/sparc/cpu/leon3/start.S

   1 /* This is where the SPARC/LEON3 starts
   2  * Copyright (C) 2007,
   3  * Daniel Hellstrom, daniel@gaisler.com
   4  *
   5  * SPDX-License-Identifier:     GPL-2.0+
   6  */
   7
   8 #include <asm-offsets.h>
   9 #include <config.h>
  10 #include <asm/asmmacro.h>
  11 #include <asm/winmacro.h>
  12 #include <asm/psr.h>
  13 #include <asm/stack.h>
  14 #include <asm/leon.h>
  15 #include <version.h>
  16
  17 /* Entry for traps which jump to a programmer-specified trap handler.  */
  18 #define TRAPR(H)  \
  19         wr      %g0, 0xfe0, %psr; \
  20         mov     %g0, %tbr; \
  21         ba      (H); \
  22         mov     %g0, %wim;
  23
  24 #define TRAP(H) \
  25         mov     %psr, %l0; \
  26         ba      (H); \
  27         nop; nop;
  28
  29 #define TRAPI(ilevel) \
  30         mov     ilevel, %l7; \
  31         mov     %psr, %l0; \
  32         b       _irq_entry; \
  33         mov     %wim, %l3
  34
  35 /* Unexcpected trap will halt the processor by forcing it to error state */
  36 #undef BAD_TRAP
  37 #define BAD_TRAP ta 0; nop; nop; nop;
  38
  39 /* Software trap. Treat as BAD_TRAP for the time being... */
  40 #define SOFT_TRAP TRAP(_hwerr)
  41
  42 #define PSR_INIT   0x1FC0       /* Disable traps, set s and ps */
  43 #define WIM_INIT   2
  44
  45 /* All traps low-level code here must end with this macro. */
  46 #define RESTORE_ALL b ret_trap_entry; clr %l6;
  47
  48 #define WRITE_PAUSE nop;nop;nop
  49
  50 WINDOWSIZE = (16 * 4)
  51 ARGPUSHSIZE = (6 * 4)
  52 ARGPUSH = (WINDOWSIZE + 4)
  53 MINFRAME = (WINDOWSIZE + ARGPUSHSIZE + 4)
  54
  55 /* Number of register windows */
  56 #ifndef CONFIG_SYS_SPARC_NWINDOWS
  57 #error Must define number of SPARC register windows, default is 8
  58 #endif
  59
  60 #define STACK_ALIGN     8
  61 #define SA(X)   (((X)+(STACK_ALIGN-1)) & ~(STACK_ALIGN-1))
  62
  63         .section ".start", "ax"
  64         .globl  _start, start, _trap_table
  65         .globl  _irq_entry, nmi_trap
  66         .globl  _reset_reloc
  67
  68 /* at address 0
  69  * Hardware traps
  70  */
  71 start:
  72 _start:
  73 _trap_table:
  74         TRAPR(_hardreset);              ! 00 reset trap
  75         BAD_TRAP;                       ! 01 instruction_access_exception
  76         BAD_TRAP;                       ! 02 illegal_instruction
  77         BAD_TRAP;                       ! 03 priveleged_instruction
  78         BAD_TRAP;                       ! 04 fp_disabled
  79         TRAP(_window_overflow);         ! 05 window_overflow
  80         TRAP(_window_underflow);        ! 06 window_underflow
  81         BAD_TRAP;                       ! 07 Memory Address Not Aligned
  82         BAD_TRAP;                       ! 08 Floating Point Exception
  83         BAD_TRAP;                       ! 09 Data Miss Exception
  84         BAD_TRAP;                       ! 0a Tagged Instruction Ovrflw
  85         BAD_TRAP;                       ! 0b Watchpoint Detected
  86         BAD_TRAP;                       ! 0c
  87         BAD_TRAP;                       ! 0d
  88         BAD_TRAP;                       ! 0e
  89         BAD_TRAP;                       ! 0f
  90         BAD_TRAP;                       ! 10
  91         TRAPI(1);                       ! 11 IRQ level 1
  92         TRAPI(2);                       ! 12 IRQ level 2
  93         TRAPI(3);                       ! 13 IRQ level 3
  94         TRAPI(4);                       ! 14 IRQ level 4
  95         TRAPI(5);                       ! 15 IRQ level 5
  96         TRAPI(6);                       ! 16 IRQ level 6
  97         TRAPI(7);                       ! 17 IRQ level 7
  98         TRAPI(8);                       ! 18 IRQ level 8
  99         TRAPI(9);                       ! 19 IRQ level 9
 100         TRAPI(10);                      ! 1a IRQ level 10
 101         TRAPI(11);                      ! 1b IRQ level 11
 102         TRAPI(12);                      ! 1c IRQ level 12
 103         TRAPI(13);                      ! 1d IRQ level 13
 104         TRAPI(14);                      ! 1e IRQ level 14
 105         TRAP(_nmi_trap);                ! 1f IRQ level 15 /
 106                                         ! NMI (non maskable interrupt)
 107         BAD_TRAP;                       ! 20 r_register_access_error
 108         BAD_TRAP;                       ! 21 instruction access error
 109         BAD_TRAP;                       ! 22
 110         BAD_TRAP;                       ! 23
 111         BAD_TRAP;                       ! 24 co-processor disabled
 112         BAD_TRAP;                       ! 25 uniplemented FLUSH
 113         BAD_TRAP;                       ! 26
 114         BAD_TRAP;                       ! 27
 115         BAD_TRAP;                       ! 28 co-processor exception
 116         BAD_TRAP;                       ! 29 data access error
 117         BAD_TRAP;                       ! 2a division by zero
 118         BAD_TRAP;                       ! 2b data store error
 119         BAD_TRAP;                       ! 2c data access MMU miss
 120         BAD_TRAP;                       ! 2d
 121         BAD_TRAP;                       ! 2e
 122         BAD_TRAP;                       ! 2f
 123         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 30-33
 124         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 34-37
 125         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 38-3b
 126         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 3c-3f
 127         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 40-43
 128         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 44-47
 129         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 48-4b
 130         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 4c-4f
 131         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 50-53
 132         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 54-57
 133         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 58-5b
 134         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 5c-5f
 135
 136         /* implementaion dependent */
 137         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 60-63
 138         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 64-67
 139         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 68-6b
 140         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 6c-6f
 141         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 70-73
 142         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 74-77
 143         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 78-7b
 144         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 7c-7f
 145
 146         /* Software traps, not handled */
 147         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! 80-83
 148         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! 84-87
 149         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! 88-8b
 150         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! 8c-8f
 151         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! 90-93
 152         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! 94-97
 153         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! 98-9b
 154         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! 9c-9f
 155         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! a0-a3
 156         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! a4-a7
 157         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! a8-ab
 158         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! ac-af
 159         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! b0-b3
 160         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! b4-b7
 161         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! b8-bb
 162         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! bc-bf
 163         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! c0-c3
 164         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! c4-c7
 165         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! c8-cb
 166         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! cc-cf
 167         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! d0-d3
 168         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! d4-d7
 169         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! d8-db
 170         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! dc-df
 171         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! e0-e3
 172         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! e4-e7
 173         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! e8-eb
 174         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! ec-ef
 175         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! f0-f3
 176         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! f4-f7
 177         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! f8-fb
 178         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! fc-ff
 179 /*
 180  * Version string
 181  */
 182
 183         .data
 184         .extern leon3_snooping_avail
 185         .globl  version_string
 186 version_string:
 187         .ascii U_BOOT_VERSION_STRING, "\0"
 188
 189         .section        ".text"
 190         .align 4
 191
 192 _hardreset:
 193 1000:
 194         flush
 195
 196         /* Enable I/D-Cache and Snooping */
 197         set     0x0081000f, %g2
 198         sta     %g2, [%g0] 2
 199
 200         mov     %g0, %y
 201         clr     %g1
 202         clr     %g2
 203         clr     %g3
 204         clr     %g4
 205         clr     %g5
 206         clr     %g6
 207         clr     %g7
 208
 209         mov     %asr17, %g3
 210         and     %g3, 0x1f, %g3
 211 clear_window:
 212         mov     %g0, %l0
 213         mov     %g0, %l1
 214         mov     %g0, %l2
 215         mov     %g0, %l3
 216         mov     %g0, %l4
 217         mov     %g0, %l5
 218         mov     %g0, %l6
 219         mov     %g0, %l7
 220         mov     %g0, %o0
 221         mov     %g0, %o1
 222         mov     %g0, %o2
 223         mov     %g0, %o3
 224         mov     %g0, %o4
 225         mov     %g0, %o5
 226         mov     %g0, %o6
 227         mov     %g0, %o7
 228         subcc   %g3, 1, %g3
 229         bge     clear_window
 230         save
 231
 232 wininit:
 233         set     WIM_INIT, %g3
 234         mov     %g3, %wim
 235
 236 stackp:
 237         set     CONFIG_SYS_INIT_SP_OFFSET, %fp
 238         andn    %fp, 0x0f, %fp
 239         sub     %fp, 64, %sp
 240
 241 cpu_init_unreloc:
 242         call    cpu_init_f
 243         nop
 244
 245 /* un relocated start address of monitor */
 246 #define TEXT_START _text
 247
 248 /* un relocated end address of monitor */
 249 #define DATA_END __init_end
 250
 251 reloc:
 252         set     TEXT_START,%g2
 253         set     DATA_END,%g3
 254         set     CONFIG_SYS_RELOC_MONITOR_BASE,%g4
 255 reloc_loop:
 256         ldd     [%g2],%l0
 257         ldd     [%g2+8],%l2
 258         std     %l0,[%g4]
 259         std     %l2,[%g4+8]
 260         inc     16,%g2
 261         subcc   %g3,%g2,%g0
 262         bne     reloc_loop
 263         inc     16,%g4
 264
 265         clr     %l0
 266         clr     %l1
 267         clr     %l2
 268         clr     %l3
 269         clr     %g2
 270
 271 /* register g4 contain address to start
 272  * This means that BSS must be directly after data and code segments
 273  *
 274  * g3 is length of bss = (__bss_end-__bss_start)
 275  *
 276  */
 277
 278 clr_bss:
 279 /* clear bss area (the relocated) */
 280         set     __bss_start,%g2
 281         set     __bss_end,%g3
 282         sub     %g3,%g2,%g3
 283         add     %g3,%g4,%g3
 284         clr     %g1     /* std %g0 uses g0 and g1 */
 285 /* clearing 16byte a time ==> linker script need to align to 16 byte offset */
 286 clr_bss_16:
 287         std     %g0,[%g4]
 288         std     %g0,[%g4+8]
 289         inc     16,%g4
 290         cmp     %g3,%g4
 291         bne     clr_bss_16
 292         nop
 293
 294 /* add offsets to GOT table */
 295 fixup_got:
 296         set     __got_start,%g4
 297         set     __got_end,%g3
 298 /*
 299  * new got offset = (old GOT-PTR (read with ld) -
 300  *   CONFIG_SYS_RELOC_MONITOR_BASE(from define) ) +
 301  *   Destination Address (from define)
 302  */
 303         set     CONFIG_SYS_RELOC_MONITOR_BASE,%g2
 304         set     TEXT_START, %g1
 305         add     %g4,%g2,%g4
 306         sub     %g4,%g1,%g4
 307         add     %g3,%g2,%g3
 308         sub     %g3,%g1,%g3
 309         sub     %g2,%g1,%g2     ! prepare register with (new base address) -
 310                                 !  (old base address)
 311 got_loop:
 312         ld      [%g4],%l0       ! load old GOT-PTR
 313         add     %l0,%g2,%l0     ! increase with (new base address) -
 314                                 !  (old base)
 315         st      %l0,[%g4]
 316         inc     4,%g4
 317         cmp     %g3,%g4
 318         bne     got_loop
 319         nop
 320
 321 prom_relocate:
 322         set     __prom_start, %g2
 323         set     __prom_end, %g3
 324         set     CONFIG_SYS_PROM_OFFSET, %g4
 325
 326 prom_relocate_loop:
 327         ldd     [%g2],%l0
 328         ldd     [%g2+8],%l2
 329         std     %l0,[%g4]
 330         std     %l2,[%g4+8]
 331         inc     16,%g2
 332         subcc   %g3,%g2,%g0
 333         bne     prom_relocate_loop
 334         inc     16,%g4
 335
 336 /* Trap table has been moved, lets tell CPU about
 337  * the new trap table address
 338  */
 339
 340         set     CONFIG_SYS_RELOC_MONITOR_BASE, %g2
 341         wr      %g0, %g2, %tbr
 342         nop
 343         nop
 344         nop
 345
 346 /* If CACHE snooping is available in hardware the
 347  * variable leon3_snooping_avail will be set to
 348  * 0x800000 else 0.
 349  */
 350 snoop_detect:
 351         sethi   %hi(0x00800000), %o0
 352         lda     [%g0] 2, %o1
 353         and     %o0, %o1, %o0
 354         sethi   %hi(leon3_snooping_avail+CONFIG_SYS_RELOC_MONITOR_BASE-CONFIG_SYS_TEXT_BASE), %o1
 355         st      %o0, [%lo(leon3_snooping_avail+CONFIG_SYS_RELOC_MONITOR_BASE-CONFIG_SYS_TEXT_BASE)+%o1]
 356
 357 /*      call    relocate*/
 358         nop
 359 /* Call relocated init functions */
 360 jump:
 361         set     cpu_init_f2,%o1
 362         set     CONFIG_SYS_RELOC_MONITOR_BASE,%o2
 363         add     %o1,%o2,%o1
 364         sub     %o1,%g1,%o1
 365         call    %o1
 366         clr     %o0
 367
 368         set     board_init_f,%o1
 369         set     CONFIG_SYS_RELOC_MONITOR_BASE,%o2
 370         add     %o1,%o2,%o1
 371         sub     %o1,%g1,%o1
 372         call    %o1
 373         clr     %o0
 374
 375 dead:   ta 0                            ! if call returns...
 376         nop
 377
 378 /* Interrupt handler caller,
 379  * reg L7: interrupt number
 380  * reg L0: psr after interrupt
 381  * reg L1: PC
 382  * reg L2: next PC
 383  * reg L3: wim
 384  */
 385 _irq_entry:
 386         SAVE_ALL
 387
 388         or      %l0, PSR_PIL, %g2
 389         wr      %g2, 0x0, %psr
 390         WRITE_PAUSE
 391         wr      %g2, PSR_ET, %psr
 392         WRITE_PAUSE
 393         mov     %l7, %o0                ! irq level
 394         set     handler_irq, %o1
 395         set     (CONFIG_SYS_RELOC_MONITOR_BASE-CONFIG_SYS_TEXT_BASE), %o2
 396         add     %o1, %o2, %o1
 397         call    %o1
 398         add     %sp, SF_REGS_SZ, %o1    ! pt_regs ptr
 399         or      %l0, PSR_PIL, %g2       ! restore PIL after handler_irq
 400         wr      %g2, PSR_ET, %psr       ! keep ET up
 401         WRITE_PAUSE
 402
 403         RESTORE_ALL
 404
 405 !Window overflow trap handler.
 406         .global _window_overflow
 407
 408 _window_overflow:
 409
 410         mov     %wim, %l3               ! Calculate next WIM
 411         mov     %g1, %l7
 412         srl     %l3, 1, %g1
 413         sll     %l3, (CONFIG_SYS_SPARC_NWINDOWS-1) , %l4
 414         or      %l4, %g1, %g1
 415
 416         save                            ! Get into window to be saved.
 417         mov     %g1, %wim
 418         nop;
 419         nop;
 420         nop
 421         st      %l0, [%sp + 0];
 422         st      %l1, [%sp + 4];
 423         st      %l2, [%sp + 8];
 424         st      %l3, [%sp + 12];
 425         st      %l4, [%sp + 16];
 426         st      %l5, [%sp + 20];
 427         st      %l6, [%sp + 24];
 428         st      %l7, [%sp + 28];
 429         st      %i0, [%sp + 32];
 430         st      %i1, [%sp + 36];
 431         st      %i2, [%sp + 40];
 432         st      %i3, [%sp + 44];
 433         st      %i4, [%sp + 48];
 434         st      %i5, [%sp + 52];
 435         st      %i6, [%sp + 56];
 436         st      %i7, [%sp + 60];
 437         restore                         ! Go back to trap window.
 438         mov     %l7, %g1
 439         jmp     %l1                     ! Re-execute save.
 440         rett    %l2
 441
 442 /* Window underflow trap handler.  */
 443
 444         .global  _window_underflow
 445
 446 _window_underflow:
 447
 448         mov  %wim, %l3                  ! Calculate next WIM
 449         sll  %l3, 1, %l4
 450         srl  %l3, (CONFIG_SYS_SPARC_NWINDOWS-1), %l5
 451         or   %l5, %l4, %l5
 452         mov  %l5, %wim
 453         nop; nop; nop
 454         restore                         ! Two restores to get into the
 455         restore                         ! window to restore
 456         ld      [%sp + 0], %l0;         ! Restore window from the stack
 457         ld      [%sp + 4], %l1;
 458         ld      [%sp + 8], %l2;
 459         ld      [%sp + 12], %l3;
 460         ld      [%sp + 16], %l4;
 461         ld      [%sp + 20], %l5;
 462         ld      [%sp + 24], %l6;
 463         ld      [%sp + 28], %l7;
 464         ld      [%sp + 32], %i0;
 465         ld      [%sp + 36], %i1;
 466         ld      [%sp + 40], %i2;
 467         ld      [%sp + 44], %i3;
 468         ld      [%sp + 48], %i4;
 469         ld      [%sp + 52], %i5;
 470         ld      [%sp + 56], %i6;
 471         ld      [%sp + 60], %i7;
 472         save                            ! Get back to the trap window.
 473         save
 474         jmp     %l1                     ! Re-execute restore.
 475         rett    %l2
 476
 477         retl
 478
 479 _nmi_trap:
 480         nop
 481         jmp %l1
 482         rett %l2
 483
 484 _hwerr:
 485         ta 0
 486         nop
 487         nop
 488         b _hwerr                        ! loop infinite
 489         nop
 490
 491 /* Registers to not touch at all. */
 492 #define t_psr      l0 /* Set by caller */
 493 #define t_pc       l1 /* Set by caller */
 494 #define t_npc      l2 /* Set by caller */
 495 #define t_wim      l3 /* Set by caller */
 496 #define t_twinmask l4 /* Set at beginning of this entry routine. */
 497 #define t_kstack   l5 /* Set right before pt_regs frame is built */
 498 #define t_retpc    l6 /* If you change this, change winmacro.h header file */
 499 #define t_systable l7 /* Never touch this, could be the syscall table ptr. */
 500 #define curptr     g6 /* Set after pt_regs frame is built */
 501
 502 trap_setup:
 503 /* build a pt_regs trap frame. */
 504         sub     %fp, (SF_REGS_SZ + PT_REGS_SZ), %t_kstack
 505         PT_STORE_ALL(t_kstack, t_psr, t_pc, t_npc, g2)
 506
 507         /* See if we are in the trap window. */
 508         mov     1, %t_twinmask
 509         sll     %t_twinmask, %t_psr, %t_twinmask ! t_twinmask = (1 << psr)
 510         andcc   %t_twinmask, %t_wim, %g0
 511         beq     1f              ! in trap window, clean up
 512         nop
 513
 514         /*-------------------------------------------------
 515          * Spill , adjust %wim and go.
 516          */
 517         srl     %t_wim, 0x1, %g2                ! begin computation of new %wim
 518
 519         set     (CONFIG_SYS_SPARC_NWINDOWS-1), %g3      !NWINDOWS-1
 520
 521         sll     %t_wim, %g3, %t_wim     ! NWINDOWS-1
 522         or      %t_wim, %g2, %g2
 523         and     %g2, 0xff, %g2
 524
 525         save    %g0, %g0, %g0           ! get in window to be saved
 526
 527         /* Set new %wim value */
 528         wr      %g2, 0x0, %wim
 529
 530         /* Save the kernel window onto the corresponding stack. */
 531         RW_STORE(sp)
 532
 533         restore %g0, %g0, %g0
 534         /*-------------------------------------------------*/
 535
 536 1:
 537         /* Trap from kernel with a window available.
 538          * Just do it...
 539          */
 540         jmpl    %t_retpc + 0x8, %g0     ! return to caller
 541          mov    %t_kstack, %sp          ! jump onto new stack
 542
 543 #define twin_tmp1 l4
 544 #define glob_tmp  g4
 545 #define curptr    g6
 546 ret_trap_entry:
 547         wr      %t_psr, 0x0, %psr       ! enable nesting again, clear ET
 548
 549         /* Will the rett land us in the invalid window? */
 550         mov     2, %g1
 551         sll     %g1, %t_psr, %g1
 552
 553         set     CONFIG_SYS_SPARC_NWINDOWS, %g2  !NWINDOWS
 554
 555         srl     %g1, %g2, %g2
 556         or      %g1, %g2, %g1
 557         rd      %wim, %g2
 558         andcc   %g2, %g1, %g0
 559         be      1f              ! Nope, just return from the trap
 560          sll    %g2, 0x1, %g1
 561
 562         /* We have to grab a window before returning. */
 563         set     (CONFIG_SYS_SPARC_NWINDOWS-1), %g3      !NWINDOWS-1
 564
 565         srl     %g2, %g3,  %g2
 566         or      %g1, %g2, %g1
 567         and     %g1, 0xff, %g1
 568
 569         wr      %g1, 0x0, %wim
 570
 571         /* Grrr, make sure we load from the right %sp... */
 572         PT_LOAD_ALL(sp, t_psr, t_pc, t_npc, g1)
 573
 574         restore %g0, %g0, %g0
 575         RW_LOAD(sp)
 576         b       2f
 577         save    %g0, %g0, %g0
 578
 579         /* Reload the entire frame in case this is from a
 580          * kernel system call or whatever...
 581          */
 582 1:
 583         PT_LOAD_ALL(sp, t_psr, t_pc, t_npc, g1)
 584 2:
 585         wr      %t_psr, 0x0, %psr
 586         nop;
 587         nop;
 588         nop
 589
 590         jmp     %t_pc
 591         rett    %t_npc
 592
 593 /* This is called from relocated C-code.
 594  * It resets the system by jumping to _start
 595  */
 596 _reset_reloc:
 597         set     start, %l0
 598         call    %l0
 599         nop