arch/nios2/cpu/start.S

   1 /*
   2  * (C) Copyright 2004, Psyent Corporation <www.psyent.com>
   3  * Scott McNutt <smcnutt@psyent.com>
   4  *
   5  * SPDX-License-Identifier:     GPL-2.0+
   6  */
   7
   8 #include <asm-offsets.h>
   9 #include <config.h>
  10 #include <version.h>
  11
  12 /*
  13  * icache and dcache configuration used only for start.S.
  14  * the values are chosen so that it will work for all configuration.
  15  */
  16 #define ICACHE_LINE_SIZE        32 /* fixed 32 */
  17 #define ICACHE_SIZE_MAX         0x10000 /* 64k max */
  18 #define DCACHE_LINE_SIZE_MIN    4 /* 4, 16, 32 */
  19 #define DCACHE_SIZE_MAX         0x10000 /* 64k max */
  20
  21         /* RESTART */
  22         .text
  23         .global _start, _except_start, _except_end
  24
  25 _start:
  26         wrctl   status, r0              /* Disable interrupts */
  27         /*
  28          * ICACHE INIT -- only the icache line at the reset address
  29          * is invalidated at reset. So the init must stay within
  30          * the cache line size (8 words). If GERMS is used, we'll
  31          * just be invalidating the cache a second time. If cache
  32          * is not implemented initi behaves as nop.
  33          */
  34         ori     r4, r0, %lo(ICACHE_LINE_SIZE)
  35         movhi   r5, %hi(ICACHE_SIZE_MAX)
  36         ori     r5, r5, %lo(ICACHE_SIZE_MAX)
  37 0:      initi   r5
  38         sub     r5, r5, r4
  39         bgt     r5, r0, 0b
  40         br      _except_end     /* Skip the tramp */
  41
  42         /*
  43          * EXCEPTION TRAMPOLINE -- the following gets copied
  44          * to the exception address (below), but is otherwise at the
  45          * default exception vector offset (0x0020).
  46          */
  47 _except_start:
  48         movhi   et, %hi(_exception)
  49         ori     et, et, %lo(_exception)
  50         jmp     et
  51 _except_end:
  52
  53         /*
  54          * INTERRUPTS -- for now, all interrupts masked and globally
  55          * disabled.
  56          */
  57         wrctl   ienable, r0             /* All disabled */
  58
  59         /*
  60          * DCACHE INIT -- if dcache not implemented, initd behaves as
  61          * nop.
  62          */
  63         ori     r4, r0, %lo(DCACHE_LINE_SIZE_MIN)
  64         movhi   r5, %hi(DCACHE_SIZE_MAX)
  65         ori     r5, r5, %lo(DCACHE_SIZE_MAX)
  66         mov     r6, r0
  67 1:      initd   0(r6)
  68         add     r6, r6, r4
  69         bltu    r6, r5, 1b
  70
  71         /*
  72          * RELOCATE CODE, DATA & COMMAND TABLE -- the following code
  73          * assumes code, data and the command table are all
  74          * contiguous. This lets us relocate everything as a single
  75          * block. Make sure the linker script matches this ;-)
  76          */
  77         nextpc  r4
  78 _cur:   movhi   r5, %hi(_cur - _start)
  79         ori     r5, r5, %lo(_cur - _start)
  80         sub     r4, r4, r5              /* r4 <- cur _start */
  81         mov     r8, r4
  82         movhi   r5, %hi(_start)
  83         ori     r5, r5, %lo(_start)     /* r5 <- linked _start */
  84         beq     r4, r5, 3f
  85
  86         movhi   r6, %hi(CONFIG_SYS_MONITOR_LEN)
  87         ori     r6, r6, %lo(CONFIG_SYS_MONITOR_LEN)
  88         add     r6, r6, r5
  89 2:      ldwio   r7, 0(r4)
  90         addi    r4, r4, 4
  91         stwio   r7, 0(r5)
  92         addi    r5, r5, 4
  93         bne     r5, r6, 2b
  94 3:
  95
  96         /* JUMP TO RELOC ADDR */
  97         movhi   r4, %hi(_reloc)
  98         ori     r4, r4, %lo(_reloc)
  99         jmp     r4
 100 _reloc:
 101
 102         /* STACK INIT -- zero top two words for call back chain. */
 103         movhi   sp, %hi(CONFIG_SYS_INIT_SP)
 104         ori     sp, sp, %lo(CONFIG_SYS_INIT_SP)
 105         addi    sp, sp, -8
 106         stw     r0, 0(sp)
 107         stw     r0, 4(sp)
 108         mov     fp, sp
 109
 110         /* Allocate and zero GD, update SP */
 111         mov     r4, sp
 112         movhi   r2, %hi(board_init_f_mem@h)
 113         ori     r2, r2, %lo(board_init_f_mem@h)
 114         callr   r2
 115
 116         /* Update stack- and frame-pointers */
 117         mov     sp, r2
 118         mov     fp, sp
 119
 120         /* Call board_init_f -- never returns */
 121         mov     r4, r0
 122         movhi   r2, %hi(board_init_f@h)
 123         ori     r2, r2, %lo(board_init_f@h)
 124         callr   r2
 125
 126         /*
 127          * NEVER RETURNS -- but branch to the _start just
 128          * in case ;-)
 129          */
 130         br      _start
 131
 132         /*
 133          * relocate_code -- Nios2 handles the relocation above. But
 134          * the generic board code monkeys with the heap, stack, etc.
 135          * (it makes some assumptions that may not be appropriate
 136          * for Nios). Nevertheless, we capitulate here.
 137          *
 138          * We'll call the board_init_r from here since this isn't
 139          * supposed to return.
 140          *
 141          * void relocate_code (ulong sp, gd_t *global_data,
 142          *                      ulong reloc_addr)
 143          *                      __attribute__ ((noreturn));
 144          */
 145         .text
 146         .global relocate_code
 147
 148 relocate_code:
 149         mov     sp, r4          /* Set the new sp */
 150         mov     r4, r5
 151
 152         /*
 153          * ZERO BSS/SBSS -- bss and sbss are assumed to be adjacent
 154          * and between __bss_start and __bss_end.
 155          */
 156         movhi   r5, %hi(__bss_start)
 157         ori     r5, r5, %lo(__bss_start)
 158         movhi   r6, %hi(__bss_end)
 159         ori     r6, r6, %lo(__bss_end)
 160         beq     r5, r6, 5f
 161
 162 4:      stwio   r0, 0(r5)
 163         addi    r5, r5, 4
 164         bne     r5, r6, 4b
 165 5:
 166
 167         movhi   r8, %hi(board_init_r@h)
 168         ori     r8, r8, %lo(board_init_r@h)
 169         callr   r8
 170         ret