arch/i386/cpu/start16.S

   1 /*
   2  *  U-boot - i386 Startup Code
   3  *
   4  *  Copyright (c) 2002, 2003 Omicron Ceti AB, Daniel Engström <denaiel@omicron.se>
   5  *
   6  * See file CREDITS for list of people who contributed to this
   7  * project.
   8  *
   9  * This program is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU General Public License as
  11  * published by the Free Software Foundation; either version 2 of
  12  * the License, or (at your option) any later version.
  13  *
  14  * This program is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  * GNU General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU General Public License
  20  * along with this program; if not, write to the Free Software
  21  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  22  * MA 02111-1307 USA
  23  */
  24
  25
  26 #define BOOT_SEG        0xffff0000      /* linear segment of boot code */
  27 #define a32             .byte 0x67;
  28 #define o32             .byte 0x66;
  29
  30 .section .start16, "ax"
  31 .code16
  32 .globl start16
  33 start16:
  34         /* First we let the BSP do some early initialization
  35          * this code have to map the flash to its final position
  36          */
  37         mov     $board_init16_ret, %bp
  38         jmp     board_init16
  39 board_init16_ret:
  40
  41         /* Turn of cache (this might require a 486-class CPU) */
  42         movl    %cr0, %eax
  43         orl     $0x60000000,%eax
  44         movl    %eax, %cr0
  45         wbinvd
  46
  47         /* load the temporary Global Descriptor Table */
  48 o32 cs  lidt    idt_ptr
  49 o32 cs  lgdt    gdt_ptr
  50
  51         /* Now, we enter protected mode */
  52         movl    %cr0, %eax
  53         orl     $1,%eax
  54         movl    %eax, %cr0
  55
  56         /* Flush the prefetch queue */
  57         jmp     ff
  58 ff:
  59         /* Tell 32-bit code it is being entered from hard-reset */
  60         movw    $0x0001, %bx
  61
  62         /* Finally jump to the 32bit initialization code */
  63         movw    $code32start, %ax
  64         movw    %ax,%bp
  65 o32 cs  ljmp    *(%bp)
  66
  67         /* 48-bit far pointer */
  68 code32start:
  69         .long   _start          /* offset */
  70         .word   0x10            /* segment */
  71
  72 idt_ptr:
  73         .word   0               /* limit */
  74         .long   0               /* base */
  75
  76 /*
  77  * The following Global Descriptor Table is just enough to get us into
  78  * 'Flat Protected Mode' - It will be discarded as soon as the final
  79  * GDT is setup in a safe location in RAM
  80  */
  81 gdt_ptr:
  82         .word   0x20            /* limit (32 bytes = 4 GDT entries) */
  83         .long   BOOT_SEG + gdt  /* base */
  84
  85         /* The GDT table ...
  86          *
  87          *       Selector       Type
  88          *       0x00           NULL
  89          *       0x08           Unused
  90          *       0x10           32bit code
  91          *       0x18           32bit data/stack
  92          */
  93
  94 gdt:
  95         .word   0, 0, 0, 0      /* NULL  */
  96         .word   0, 0, 0, 0      /* unused */
  97
  98         .word   0xFFFF          /* 4Gb - (0x100000*0x1000 = 4Gb) */
  99         .word   0               /* base address = 0 */
 100         .word   0x9B00          /* code read/exec */
 101         .word   0x00CF          /* granularity = 4096, 386 (+5th nibble of limit) */
 102
 103         .word   0xFFFF          /* 4Gb - (0x100000*0x1000 = 4Gb) */
 104         .word   0x0             /* base address = 0 */
 105         .word   0x9300          /* data read/write */
 106         .word   0x00CF          /* granularity = 4096, 386 (+5th nibble of limit) */