arch/i386/cpu/start16.S

   1 /*
   2  *  U-boot - i386 Startup Code
   3  *
   4  *  Copyright (c) 2002, 2003 Omicron Ceti AB, Daniel Engström <denaiel@omicron.se>
   5  *
   6  * See file CREDITS for list of people who contributed to this
   7  * project.
   8  *
   9  * This program is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU General Public License as
  11  * published by the Free Software Foundation; either version 2 of
  12  * the License, or (at your option) any later version.
  13  *
  14  * This program is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  * GNU General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU General Public License
  20  * along with this program; if not, write to the Free Software
  21  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  22  * MA 02111-1307 USA
  23  */
  24
  25 #include <asm/global_data.h>
  26 #include <asm/processor-flags.h>
  27
  28 #define BOOT_SEG        0xffff0000      /* linear segment of boot code */
  29 #define a32             .byte 0x67;
  30 #define o32             .byte 0x66;
  31
  32 .section .start16, "ax"
  33 .code16
  34 .globl start16
  35 start16:
  36         /* Set the Cold Boot / Hard Reset flag */
  37         movl    $GD_FLG_COLD_BOOT, %ebx
  38
  39         /*
  40          * First we let the BSP do some early initialization
  41          * this code have to map the flash to its final position
  42          */
  43         jmp     board_init16
  44 .globl board_init16_ret
  45 board_init16_ret:
  46
  47         /* Turn of cache (this might require a 486-class CPU) */
  48         movl    %cr0, %eax
  49         orl     $(X86_CR0_NW & X86_CR0_CD), %eax
  50         movl    %eax, %cr0
  51         wbinvd
  52
  53         /* load the temporary Global Descriptor Table */
  54 o32 cs  lidt    idt_ptr
  55 o32 cs  lgdt    gdt_ptr
  56
  57         /* Now, we enter protected mode */
  58         movl    %cr0, %eax
  59         orl     $X86_CR0_PE, %eax
  60         movl    %eax, %cr0
  61
  62         /* Flush the prefetch queue */
  63         jmp     ff
  64 ff:
  65         /* Finally jump to the 32bit initialization code */
  66         movw    $code32start, %ax
  67         movw    %ax, %bp
  68 o32 cs  ljmp    *(%bp)
  69
  70         /* 48-bit far pointer */
  71 code32start:
  72         .long   _start          /* offset */
  73         .word   0x10            /* segment */
  74
  75 idt_ptr:
  76         .word   0               /* limit */
  77         .long   0               /* base */
  78
  79 /*
  80  * The following Global Descriptor Table is just enough to get us into
  81  * 'Flat Protected Mode' - It will be discarded as soon as the final
  82  * GDT is setup in a safe location in RAM
  83  */
  84 gdt_ptr:
  85         .word   0x20            /* limit (32 bytes = 4 GDT entries) */
  86         .long   BOOT_SEG + gdt  /* base */
  87
  88         /* The GDT table ...
  89          *
  90          *       Selector       Type
  91          *       0x00           NULL
  92          *       0x08           Unused
  93          *       0x10           32bit code
  94          *       0x18           32bit data/stack
  95          */
  96
  97 gdt:
  98         .word   0, 0, 0, 0      /* NULL  */
  99         .word   0, 0, 0, 0      /* unused */
 100
 101         .word   0xFFFF          /* 4Gb - (0x100000*0x1000 = 4Gb) */
 102         .word   0               /* base address = 0 */
 103         .word   0x9B00          /* code read/exec */
 104         .word   0x00CF          /* granularity = 4096, 386 (+5th nibble of limit) */
 105
 106         .word   0xFFFF          /* 4Gb - (0x100000*0x1000 = 4Gb) */
 107         .word   0x0             /* base address = 0 */
 108         .word   0x9300          /* data read/write */
 109         .word   0x00CF          /* granularity = 4096, 386 (+5th nibble of limit) */