arch/arm/lib/crt0.S

   1 /* SPDX-License-Identifier: GPL-2.0+ */
   2 /*
   3  *  crt0 - C-runtime startup Code for ARM U-Boot
   4  *
   5  *  Copyright (c) 2012  Albert ARIBAUD <albert.u.boot@aribaud.net>
   6  */
   7
   8 #include <config.h>
   9 #include <asm-offsets.h>
  10 #include <linux/linkage.h>
  11 #include <asm/assembler.h>
  12
  13 /*
  14  * This file handles the target-independent stages of the U-Boot
  15  * start-up where a C runtime environment is needed. Its entry point
  16  * is _main and is branched into from the target's start.S file.
  17  *
  18  * _main execution sequence is:
  19  *
  20  * 1. Set up initial environment for calling board_init_f().
  21  *    This environment only provides a stack and a place to store
  22  *    the GD ('global data') structure, both located in some readily
  23  *    available RAM (SRAM, locked cache...). In this context, VARIABLE
  24  *    global data, initialized or not (BSS), are UNAVAILABLE; only
  25  *    CONSTANT initialized data are available. GD should be zeroed
  26  *    before board_init_f() is called.
  27  *
  28  * 2. Call board_init_f(). This function prepares the hardware for
  29  *    execution from system RAM (DRAM, DDR...) As system RAM may not
  30  *    be available yet, , board_init_f() must use the current GD to
  31  *    store any data which must be passed on to later stages. These
  32  *    data include the relocation destination, the future stack, and
  33  *    the future GD location.
  34  *
  35  * 3. Set up intermediate environment where the stack and GD are the
  36  *    ones allocated by board_init_f() in system RAM, but BSS and
  37  *    initialized non-const data are still not available.
  38  *
  39  * 4a.For U-Boot proper (not SPL), call relocate_code(). This function
  40  *    relocates U-Boot from its current location into the relocation
  41  *    destination computed by board_init_f().
  42  *
  43  * 4b.For SPL, board_init_f() just returns (to crt0). There is no
  44  *    code relocation in SPL.
  45  *
  46  * 5. Set up final environment for calling board_init_r(). This
  47  *    environment has BSS (initialized to 0), initialized non-const
  48  *    data (initialized to their intended value), and stack in system
  49  *    RAM (for SPL moving the stack and GD into RAM is optional - see
  50  *    CONFIG_SPL_STACK_R). GD has retained values set by board_init_f().
  51  *
  52  * 6. For U-Boot proper (not SPL), some CPUs have some work left to do
  53  *    at this point regarding memory, so call c_runtime_cpu_setup.
  54  *
  55  * 7. Branch to board_init_r().
  56  *
  57  * For more information see 'Board Initialisation Flow in README.
  58  */
  59
  60 /*
  61  * entry point of crt0 sequence
  62  */
  63
  64 ENTRY(_main)
  65
  66 /*
  67  * Set up initial C runtime environment and call board_init_f(0).
  68  */
  69
  70 #if defined(CONFIG_SPL_BUILD) && defined(CONFIG_SPL_STACK)
  71         ldr     r0, =(CONFIG_SPL_STACK)
  72 #else
  73         ldr     r0, =(CONFIG_SYS_INIT_SP_ADDR)
  74 #endif
  75         bic     r0, r0, #7      /* 8-byte alignment for ABI compliance */
  76         mov     sp, r0
  77         bl      board_init_f_alloc_reserve
  78         mov     sp, r0
  79         /* set up gd here, outside any C code */
  80         mov     r9, r0
  81         bl      board_init_f_init_reserve
  82
  83         mov     r0, #0
  84         bl      board_init_f
  85
  86 #if ! defined(CONFIG_SPL_BUILD)
  87
  88 /*
  89  * Set up intermediate environment (new sp and gd) and call
  90  * relocate_code(addr_moni). Trick here is that we'll return
  91  * 'here' but relocated.
  92  */
  93
  94         ldr     r0, [r9, #GD_START_ADDR_SP]     /* sp = gd->start_addr_sp */
  95         bic     r0, r0, #7      /* 8-byte alignment for ABI compliance */
  96         mov     sp, r0
  97         ldr     r9, [r9, #GD_BD]                /* r9 = gd->bd */
  98         sub     r9, r9, #GD_SIZE                /* new GD is below bd */
  99
 100         adr     lr, here
 101         ldr     r0, [r9, #GD_RELOC_OFF]         /* r0 = gd->reloc_off */
 102         add     lr, lr, r0
 103 #if defined(CONFIG_CPU_V7M)
 104         orr     lr, #1                          /* As required by Thumb-only */
 105 #endif
 106         ldr     r0, [r9, #GD_RELOCADDR]         /* r0 = gd->relocaddr */
 107         b       relocate_code
 108 here:
 109 /*
 110  * now relocate vectors
 111  */
 112
 113         bl      relocate_vectors
 114
 115 /* Set up final (full) environment */
 116
 117         bl      c_runtime_cpu_setup     /* we still call old routine here */
 118 #endif
 119 #if !defined(CONFIG_SPL_BUILD) || defined(CONFIG_SPL_FRAMEWORK)
 120 # ifdef CONFIG_SPL_BUILD
 121         /* Use a DRAM stack for the rest of SPL, if requested */
 122         bl      spl_relocate_stack_gd
 123         cmp     r0, #0
 124         movne   sp, r0
 125         movne   r9, r0
 126 # endif
 127         ldr     r0, =__bss_start        /* this is auto-relocated! */
 128
 129 #ifdef CONFIG_USE_ARCH_MEMSET
 130         ldr     r3, =__bss_end          /* this is auto-relocated! */
 131         mov     r1, #0x00000000         /* prepare zero to clear BSS */
 132
 133         subs    r2, r3, r0              /* r2 = memset len */
 134         bl      memset
 135 #else
 136         ldr     r1, =__bss_end          /* this is auto-relocated! */
 137         mov     r2, #0x00000000         /* prepare zero to clear BSS */
 138
 139 clbss_l:cmp     r0, r1                  /* while not at end of BSS */
 140         strlo   r2, [r0]                /* clear 32-bit BSS word */
 141         addlo   r0, r0, #4              /* move to next */
 142         blo     clbss_l
 143 #endif
 144
 145 #if ! defined(CONFIG_SPL_BUILD)
 146         bl coloured_LED_init
 147         bl red_led_on
 148 #endif
 149         /* call board_init_r(gd_t *id, ulong dest_addr) */
 150         mov     r0, r9                  /* gd_t */
 151         ldr     r1, [r9, #GD_RELOCADDR] /* dest_addr */
 152         /* call board_init_r */
 153 #if CONFIG_IS_ENABLED(SYS_THUMB_BUILD)
 154         ldr     lr, =board_init_r       /* this is auto-relocated! */
 155         bx      lr
 156 #else
 157         ldr     pc, =board_init_r       /* this is auto-relocated! */
 158 #endif
 159         /* we should not return here. */
 160 #endif
 161
 162 ENDPROC(_main)