arch/arm/cpu/lh7a40x/start.S

   1 /*
   2  *  armboot - Startup Code for ARM920 CPU-core
   3  *
   4  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   5  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
   6  *  Copyright (c) 2002  Gary Jennejohn <garyj@denx.de>
   7  *
   8  * See file CREDITS for list of people who contributed to this
   9  * project.
  10  *
  11  * This program is free software; you can redistribute it and/or
  12  * modify it under the terms of the GNU General Public License as
  13  * published by the Free Software Foundation; either version 2 of
  14  * the License, or (at your option) any later version.
  15  *
  16  * This program is distributed in the hope that it will be useful,
  17  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  18  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19  * GNU General Public License for more details.
  20  *
  21  * You should have received a copy of the GNU General Public License
  22  * along with this program; if not, write to the Free Software
  23  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  24  * MA 02111-1307 USA
  25  */
  26
  27 #include <asm-offsets.h>
  28 #include <config.h>
  29 #include <version.h>
  30
  31 /*
  32  *************************************************************************
  33  *
  34  * Jump vector table as in table 3.1 in [1]
  35  *
  36  *************************************************************************
  37  */
  38
  39
  40 .globl _start
  41 _start: b       reset
  42         ldr     pc, _undefined_instruction
  43         ldr     pc, _software_interrupt
  44         ldr     pc, _prefetch_abort
  45         ldr     pc, _data_abort
  46         ldr     pc, _not_used
  47         ldr     pc, _irq
  48         ldr     pc, _fiq
  49
  50 _undefined_instruction: .word undefined_instruction
  51 _software_interrupt:    .word software_interrupt
  52 _prefetch_abort:        .word prefetch_abort
  53 _data_abort:            .word data_abort
  54 _not_used:              .word not_used
  55 _irq:                   .word irq
  56 _fiq:                   .word fiq
  57
  58         .balignl 16,0xdeadbeef
  59
  60
  61 /*
  62  *************************************************************************
  63  *
  64  * Startup Code (reset vector)
  65  *
  66  * do important init only if we don't start from memory!
  67  * relocate armboot to ram
  68  * setup stack
  69  * jump to second stage
  70  *
  71  *************************************************************************
  72  */
  73
  74 .globl _TEXT_BASE
  75 _TEXT_BASE:
  76         .word   CONFIG_SYS_TEXT_BASE
  77
  78 /*
  79  * These are defined in the board-specific linker script.
  80  */
  81 .globl _bss_start
  82 _bss_start:
  83         .word __bss_start
  84
  85 .globl _bss_end
  86 _bss_end:
  87         .word _end
  88
  89 #ifdef CONFIG_USE_IRQ
  90 /* IRQ stack memory (calculated at run-time) */
  91 .globl IRQ_STACK_START
  92 IRQ_STACK_START:
  93         .word   0x0badc0de
  94
  95 /* IRQ stack memory (calculated at run-time) */
  96 .globl FIQ_STACK_START
  97 FIQ_STACK_START:
  98         .word 0x0badc0de
  99 #endif
 100
 101 /* IRQ stack memory (calculated at run-time) + 8 bytes */
 102 .globl IRQ_STACK_START_IN
 103 IRQ_STACK_START_IN:
 104         .word   0x0badc0de
 105
 106 .globl _datarel_start
 107 _datarel_start:
 108         .word __datarel_start
 109
 110 .globl _datarelrolocal_start
 111 _datarelrolocal_start:
 112         .word __datarelrolocal_start
 113
 114 .globl _datarellocal_start
 115 _datarellocal_start:
 116         .word __datarellocal_start
 117
 118 .globl _datarelro_start
 119 _datarelro_start:
 120         .word __datarelro_start
 121
 122 .globl _got_start
 123 _got_start:
 124         .word __got_start
 125
 126 .globl _got_end
 127 _got_end:
 128         .word __got_end
 129
 130 /*
 131  * the actual reset code
 132  */
 133
 134 reset:
 135         /*
 136          * set the cpu to SVC32 mode
 137          */
 138         mrs     r0,cpsr
 139         bic     r0,r0,#0x1f
 140         orr     r0,r0,#0xd3
 141         msr     cpsr,r0
 142
 143 #define pWDTCTL         0x80001400  /* Watchdog Timer control register */
 144 #define pINTENC         0x8000050C  /* Interupt-Controller enable clear register */
 145 #define pCLKSET         0x80000420  /* clock divisor register */
 146
 147         /* disable watchdog, set watchdog control register to
 148          * all zeros (default reset)
 149          */
 150         ldr     r0, =pWDTCTL
 151         mov     r1, #0x0
 152         str     r1, [r0]
 153
 154         /*
 155          * mask all IRQs by setting all bits in the INTENC register (default)
 156          */
 157         mov     r1, #0xffffffff
 158         ldr     r0, =pINTENC
 159         str     r1, [r0]
 160
 161         /* FCLK:HCLK:PCLK = 1:2:2 */
 162         /* default FCLK is 200 MHz, using 14.7456 MHz fin */
 163         ldr     r0, =pCLKSET
 164         ldr r1, =0x0004ee39
 165 @       ldr r1, =0x0005ee39     @ 1: 2: 4
 166         str     r1, [r0]
 167
 168         /*
 169          * we do sys-critical inits only at reboot,
 170          * not when booting from ram!
 171          */
 172 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 173         bl      cpu_init_crit
 174 #endif
 175
 176 /* Set stackpointer in internal RAM to call board_init_f */
 177 call_board_init_f:
 178         ldr     sp, =(CONFIG_SYS_INIT_SP_ADDR)
 179         ldr     r0,=0x00000000
 180         bl      board_init_f
 181
 182 /*------------------------------------------------------------------------------*/
 183
 184 /*
 185  * void relocate_code (addr_sp, gd, addr_moni)
 186  *
 187  * This "function" does not return, instead it continues in RAM
 188  * after relocating the monitor code.
 189  *
 190  */
 191         .globl  relocate_code
 192 relocate_code:
 193         mov     r4, r0  /* save addr_sp */
 194         mov     r5, r1  /* save addr of gd */
 195         mov     r6, r2  /* save addr of destination */
 196         mov     r7, r2  /* save addr of destination */
 197
 198         /* Set up the stack                                                 */
 199 stack_setup:
 200         mov     sp, r4
 201
 202         adr     r0, _start
 203         ldr     r2, _TEXT_BASE
 204         ldr     r3, _bss_start
 205         sub     r2, r3, r2              /* r2 <- size of armboot            */
 206         add     r2, r0, r2              /* r2 <- source end address         */
 207         cmp     r0, r6
 208         beq     clear_bss
 209
 210 #ifndef CONFIG_SKIP_RELOCATE_UBOOT
 211 copy_loop:
 212         ldmia   r0!, {r9-r10}           /* copy from source address [r0]    */
 213         stmia   r6!, {r9-r10}           /* copy to   target address [r1]    */
 214         cmp     r0, r2                  /* until source end address [r2]    */
 215         blo     copy_loop
 216
 217 #ifndef CONFIG_PRELOADER
 218         /* fix got entries */
 219         ldr     r1, _TEXT_BASE          /* Text base */
 220         mov     r0, r7                  /* reloc addr */
 221         ldr     r2, _got_start          /* addr in Flash */
 222         ldr     r3, _got_end            /* addr in Flash */
 223         sub     r3, r3, r1
 224         add     r3, r3, r0
 225         sub     r2, r2, r1
 226         add     r2, r2, r0
 227
 228 fixloop:
 229         ldr     r4, [r2]
 230         sub     r4, r4, r1
 231         add     r4, r4, r0
 232         str     r4, [r2]
 233         add     r2, r2, #4
 234         cmp     r2, r3
 235         blo     fixloop
 236 #endif
 237 #endif  /* #ifndef CONFIG_SKIP_RELOCATE_UBOOT */
 238
 239 clear_bss:
 240 #ifndef CONFIG_PRELOADER
 241         ldr     r0, _bss_start
 242         ldr     r1, _bss_end
 243         ldr     r3, _TEXT_BASE          /* Text base */
 244         mov     r4, r7                  /* reloc addr */
 245         sub     r0, r0, r3
 246         add     r0, r0, r4
 247         sub     r1, r1, r3
 248         add     r1, r1, r4
 249         mov     r2, #0x00000000         /* clear                            */
 250
 251 clbss_l:str     r2, [r0]                /* clear loop...                    */
 252         add     r0, r0, #4
 253         cmp     r0, r1
 254         bne     clbss_l
 255 #endif
 256
 257 /*
 258  * We are done. Do not return, instead branch to second part of board
 259  * initialization, now running from RAM.
 260  */
 261         ldr     r0, _TEXT_BASE
 262         ldr     r2, _board_init_r
 263         sub     r2, r2, r0
 264         add     r2, r2, r7      /* position from board_init_r in RAM */
 265         /* setup parameters for board_init_r */
 266         mov     r0, r5          /* gd_t */
 267         mov     r1, r7          /* dest_addr */
 268         /* jump to it ... */
 269         mov     lr, r2
 270         mov     pc, lr
 271
 272 _board_init_r: .word board_init_r
 273
 274 /*
 275  *************************************************************************
 276  *
 277  * CPU_init_critical registers
 278  *
 279  * setup important registers
 280  * setup memory timing
 281  *
 282  *************************************************************************
 283  */
 284
 285
 286 cpu_init_crit:
 287         /*
 288          * flush v4 I/D caches
 289          */
 290         mov     r0, #0
 291         mcr     p15, 0, r0, c7, c7, 0   /* flush v3/v4 cache */
 292         mcr     p15, 0, r0, c8, c7, 0   /* flush v4 TLB */
 293
 294         /*
 295          * disable MMU stuff and caches
 296          */
 297         mrc     p15, 0, r0, c1, c0, 0
 298         bic     r0, r0, #0x00002300     @ clear bits 13, 9:8 (--V- --RS)
 299         bic     r0, r0, #0x00000087     @ clear bits 7, 2:0 (B--- -CAM)
 300         orr     r0, r0, #0x00000002     @ set bit 2 (A) Align
 301         orr     r0, r0, #0x00001000     @ set bit 12 (I) I-Cache
 302         orr     r0, r0, #0x40000000     @ set bit 30 (nF) notFastBus
 303         mcr     p15, 0, r0, c1, c0, 0
 304
 305
 306         /*
 307          * before relocating, we have to setup RAM timing
 308          * because memory timing is board-dependend, you will
 309          * find a lowlevel_init.S in your board directory.
 310          */
 311         mov     ip, lr
 312         bl      lowlevel_init
 313         mov     lr, ip
 314
 315         mov     pc, lr
 316
 317
 318 /*
 319  *************************************************************************
 320  *
 321  * Interrupt handling
 322  *
 323  *************************************************************************
 324  */
 325
 326 @
 327 @ IRQ stack frame.
 328 @
 329 #define S_FRAME_SIZE    72
 330
 331 #define S_OLD_R0        68
 332 #define S_PSR           64
 333 #define S_PC            60
 334 #define S_LR            56
 335 #define S_SP            52
 336
 337 #define S_IP            48
 338 #define S_FP            44
 339 #define S_R10           40
 340 #define S_R9            36
 341 #define S_R8            32
 342 #define S_R7            28
 343 #define S_R6            24
 344 #define S_R5            20
 345 #define S_R4            16
 346 #define S_R3            12
 347 #define S_R2            8
 348 #define S_R1            4
 349 #define S_R0            0
 350
 351 #define MODE_SVC 0x13
 352 #define I_BIT    0x80
 353
 354 /*
 355  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 356  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 357  */
 358
 359         .macro  bad_save_user_regs
 360         sub     sp, sp, #S_FRAME_SIZE
 361         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 362         ldr     r2, IRQ_STACK_START_IN
 363         ldmia   r2, {r2 - r3}                   @ get pc, cpsr
 364         add     r0, sp, #S_FRAME_SIZE           @ restore sp_SVC
 365
 366         add     r5, sp, #S_SP
 367         mov     r1, lr
 368         stmia   r5, {r0 - r3}                   @ save sp_SVC, lr_SVC, pc, cpsr
 369         mov     r0, sp
 370         .endm
 371
 372         .macro  irq_save_user_regs
 373         sub     sp, sp, #S_FRAME_SIZE
 374         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 375         add     r8, sp, #S_PC
 376         stmdb   r8, {sp, lr}^                   @ Calling SP, LR
 377         str     lr, [r8, #0]                    @ Save calling PC
 378         mrs     r6, spsr
 379         str     r6, [r8, #4]                    @ Save CPSR
 380         str     r0, [r8, #8]                    @ Save OLD_R0
 381         mov     r0, sp
 382         .endm
 383
 384         .macro  irq_restore_user_regs
 385         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 386         mov     r0, r0
 387         ldr     lr, [sp, #S_PC]                 @ Get PC
 388         add     sp, sp, #S_FRAME_SIZE
 389         subs    pc, lr, #4                      @ return & move spsr_svc into cpsr
 390         .endm
 391
 392         .macro get_bad_stack
 393         ldr     r13, IRQ_STACK_START_IN         @ setup our mode stack
 394
 395         str     lr, [r13]                       @ save caller lr / spsr
 396         mrs     lr, spsr
 397         str     lr, [r13, #4]
 398
 399         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 400         @ msr   spsr_c, r13
 401         msr     spsr, r13
 402         mov     lr, pc
 403         movs    pc, lr
 404         .endm
 405
 406         .macro get_irq_stack                    @ setup IRQ stack
 407         ldr     sp, IRQ_STACK_START
 408         .endm
 409
 410         .macro get_fiq_stack                    @ setup FIQ stack
 411         ldr     sp, FIQ_STACK_START
 412         .endm
 413
 414 /*
 415  * exception handlers
 416  */
 417         .align  5
 418 undefined_instruction:
 419         get_bad_stack
 420         bad_save_user_regs
 421         bl      do_undefined_instruction
 422
 423         .align  5
 424 software_interrupt:
 425         get_bad_stack
 426         bad_save_user_regs
 427         bl      do_software_interrupt
 428
 429         .align  5
 430 prefetch_abort:
 431         get_bad_stack
 432         bad_save_user_regs
 433         bl      do_prefetch_abort
 434
 435         .align  5
 436 data_abort:
 437         get_bad_stack
 438         bad_save_user_regs
 439         bl      do_data_abort
 440
 441         .align  5
 442 not_used:
 443         get_bad_stack
 444         bad_save_user_regs
 445         bl      do_not_used
 446
 447 #ifdef CONFIG_USE_IRQ
 448
 449         .align  5
 450 irq:
 451         get_irq_stack
 452         irq_save_user_regs
 453         bl      do_irq
 454         irq_restore_user_regs
 455
 456         .align  5
 457 fiq:
 458         get_fiq_stack
 459         /* someone ought to write a more effiction fiq_save_user_regs */
 460         irq_save_user_regs
 461         bl      do_fiq
 462         irq_restore_user_regs
 463
 464 #else
 465
 466         .align  5
 467 irq:
 468         get_bad_stack
 469         bad_save_user_regs
 470         bl      do_irq
 471
 472         .align  5
 473 fiq:
 474         get_bad_stack
 475         bad_save_user_regs
 476         bl      do_fiq
 477
 478 #endif
 479
 480         .align  5
 481 .globl reset_cpu
 482 reset_cpu:
 483         bl      disable_interrupts
 484
 485         /* Disable watchdog */
 486         ldr     r1, =pWDTCTL
 487         mov     r3, #0
 488         str     r3, [r1]
 489
 490         /* reset counter */
 491         ldr     r3, =0x00001984
 492         str     r3, [r1, #4]
 493
 494         /* Enable the watchdog */
 495         mov     r3, #1
 496         str     r3, [r1]
 497
 498 _loop_forever:
 499         b       _loop_forever