arch/arm/cpu/armv7/sunxi/u-boot-spl.lds

   1 /* SPDX-License-Identifier: GPL-2.0+ */
   2 /*
   3  * (C) Copyright 2012
   4  * Allwinner Technology Co., Ltd. <www.allwinnertech.com>
   5  * Tom Cubie <tangliang@allwinnertech.com>
   6  *
   7  * Based on omap-common/u-boot-spl.lds:
   8  *
   9  * (C) Copyright 2002
  10  * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
  11  *
  12  * (C) Copyright 2010
  13  * Texas Instruments, <www.ti.com>
  14  *      Aneesh V <aneesh@ti.com>
  15  */
  16 MEMORY { .sram : ORIGIN = IMAGE_TEXT_BASE,\
  17                 LENGTH = IMAGE_MAX_SIZE }
  18 MEMORY { .sdram : ORIGIN = CONFIG_SPL_BSS_START_ADDR, \
  19                 LENGTH = CONFIG_SPL_BSS_MAX_SIZE }
  20
  21 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  22 OUTPUT_ARCH(arm)
  23 ENTRY(_start)
  24 SECTIONS
  25 {
  26         .text      :
  27         {
  28                 __start = .;
  29                 *(.vectors)
  30                 arch/arm/cpu/armv7/start.o      (.text)
  31                 *(.text*)
  32         } > .sram
  33
  34         . = ALIGN(4);
  35         .rodata : { *(SORT_BY_ALIGNMENT(.rodata*)) } >.sram
  36
  37         . = ALIGN(4);
  38         .data : { *(SORT_BY_ALIGNMENT(.data*)) } >.sram
  39
  40         . = ALIGN(4);
  41         .u_boot_list : {
  42                 KEEP(*(SORT(.u_boot_list*)));
  43         } > .sram
  44
  45         . = ALIGN(4);
  46         __image_copy_end = .;
  47         _end = .;
  48
  49         .bss :
  50         {
  51                 . = ALIGN(4);
  52                 __bss_start = .;
  53                 *(.bss*)
  54                 . = ALIGN(4);
  55                 __bss_end = .;
  56         } > .sdram
  57 }