arch/arm/cpu/armv7/sunxi/psci_sun6i.S

   1 /*
   2  * Copyright (C) 2015 - Chen-Yu Tsai
   3  * Author: Chen-Yu Tsai <wens@csie.org>
   4  *
   5  * Based on psci_sun7i.S by Marc Zyngier <marc.zyngier@arm.com>
   6  *
   7  * This program is free software; you can redistribute it and/or modify
   8  * it under the terms of the GNU General Public License version 2 as
   9  * published by the Free Software Foundation.
  10  *
  11  * This program is distributed in the hope that it will be useful,
  12  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14  * GNU General Public License for more details.
  15  *
  16  * You should have received a copy of the GNU General Public License
  17  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18  */
  19
  20 #include <config.h>
  21 #include <asm/gic.h>
  22 #include <asm/macro.h>
  23 #include <asm/psci.h>
  24 #include <asm/arch/cpu.h>
  25
  26 /*
  27  * Memory layout:
  28  *
  29  * SECURE_RAM to text_end :
  30  *      ._secure_text section
  31  * text_end to ALIGN_PAGE(text_end):
  32  *      nothing
  33  * ALIGN_PAGE(text_end) to ALIGN_PAGE(text_end) + 0x1000)
  34  *      1kB of stack per CPU (4 CPUs max).
  35  */
  36
  37         .pushsection ._secure.text, "ax"
  38
  39         .arch_extension sec
  40
  41 #define ONE_MS                  (CONFIG_TIMER_CLK_FREQ / 1000)
  42 #define TEN_MS                  (10 * ONE_MS)
  43 #define GICD_BASE               0x1c81000
  44 #define GICC_BASE               0x1c82000
  45
  46 .macro  timer_wait      reg, ticks
  47         @ Program CNTP_TVAL
  48         movw    \reg, #(\ticks & 0xffff)
  49         movt    \reg, #(\ticks >> 16)
  50         mcr     p15, 0, \reg, c14, c2, 0
  51         isb
  52         @ Enable physical timer, mask interrupt
  53         mov     \reg, #3
  54         mcr     p15, 0, \reg, c14, c2, 1
  55         @ Poll physical timer until ISTATUS is on
  56 1:      isb
  57         mrc     p15, 0, \reg, c14, c2, 1
  58         ands    \reg, \reg, #4
  59         bne     1b
  60         @ Disable timer
  61         mov     \reg, #0
  62         mcr     p15, 0, \reg, c14, c2, 1
  63         isb
  64 .endm
  65
  66 .globl  psci_fiq_enter
  67 psci_fiq_enter:
  68         push    {r0-r12}
  69
  70         @ Switch to secure
  71         mrc     p15, 0, r7, c1, c1, 0
  72         bic     r8, r7, #1
  73         mcr     p15, 0, r8, c1, c1, 0
  74         isb
  75
  76         @ Validate reason based on IAR and acknowledge
  77         movw    r8, #(GICC_BASE & 0xffff)
  78         movt    r8, #(GICC_BASE >> 16)
  79         ldr     r9, [r8, #GICC_IAR]
  80         movw    r10, #0x3ff
  81         movt    r10, #0
  82         cmp     r9, r10                 @ skip spurious interrupt 1023
  83         beq     out
  84         movw    r10, #0x3fe             @ ...and 1022
  85         cmp     r9, r10
  86         beq     out
  87         str     r9, [r8, #GICC_EOIR]    @ acknowledge the interrupt
  88         dsb
  89
  90         @ Compute CPU number
  91         lsr     r9, r9, #10
  92         and     r9, r9, #0xf
  93
  94         movw    r8, #(SUN6I_CPUCFG_BASE & 0xffff)
  95         movt    r8, #(SUN6I_CPUCFG_BASE >> 16)
  96
  97         @ Wait for the core to enter WFI
  98         lsl     r11, r9, #6             @ x64
  99         add     r11, r11, r8
 100
 101 1:      ldr     r10, [r11, #0x48]
 102         tst     r10, #(1 << 2)
 103         bne     2f
 104         timer_wait r10, ONE_MS
 105         b       1b
 106
 107         @ Reset CPU
 108 2:      mov     r10, #0
 109         str     r10, [r11, #0x40]
 110
 111         @ Lock CPU
 112         mov     r10, #1
 113         lsl     r11, r10, r9            @ r11 is now CPU mask
 114         ldr     r10, [r8, #0x1e4]
 115         bic     r10, r10, r11
 116         str     r10, [r8, #0x1e4]
 117
 118         movw    r8, #(SUNXI_PRCM_BASE & 0xffff)
 119         movt    r8, #(SUNXI_PRCM_BASE >> 16)
 120
 121         @ Set power gating
 122         ldr     r10, [r8, #0x100]
 123         orr     r10, r10, r11
 124         str     r10, [r8, #0x100]
 125         timer_wait r10, ONE_MS
 126
 127 #ifdef CONFIG_MACH_SUN6I
 128         @ Activate power clamp
 129         lsl     r12, r9, #2             @ x4
 130         add     r12, r12, r8
 131         mov     r10, #0xff
 132         str     r10, [r12, #0x140]
 133 #endif
 134
 135         movw    r8, #(SUN6I_CPUCFG_BASE & 0xffff)
 136         movt    r8, #(SUN6I_CPUCFG_BASE >> 16)
 137
 138         @ Unlock CPU
 139         ldr     r10, [r8, #0x1e4]
 140         orr     r10, r10, r11
 141         str     r10, [r8, #0x1e4]
 142
 143         @ Restore security level
 144 out:    mcr     p15, 0, r7, c1, c1, 0
 145
 146         pop     {r0-r12}
 147         subs    pc, lr, #4
 148
 149         @ r1 = target CPU
 150         @ r2 = target PC
 151 .globl  psci_cpu_on
 152 psci_cpu_on:
 153         push    {lr}
 154
 155         mov     r0, r1
 156         bl      psci_get_cpu_stack_top  @ get stack top of target CPU
 157         str     r2, [r0]                @ store target PC at stack top
 158         dsb
 159
 160         movw    r0, #(SUN6I_CPUCFG_BASE & 0xffff)
 161         movt    r0, #(SUN6I_CPUCFG_BASE >> 16)
 162
 163         @ CPU mask
 164         and     r1, r1, #3      @ only care about first cluster
 165         mov     r4, #1
 166         lsl     r4, r4, r1
 167
 168         ldr     r6, =psci_cpu_entry
 169         str     r6, [r0, #0x1a4] @ PRIVATE_REG (boot vector)
 170
 171         @ Assert reset on target CPU
 172         mov     r6, #0
 173         lsl     r5, r1, #6      @ 64 bytes per CPU
 174         add     r5, r5, #0x40   @ Offset from base
 175         add     r5, r5, r0      @ CPU control block
 176         str     r6, [r5]        @ Reset CPU
 177
 178         @ l1 invalidate
 179         ldr     r6, [r0, #0x184] @ CPUCFG_GEN_CTRL_REG
 180         bic     r6, r6, r4
 181         str     r6, [r0, #0x184]
 182
 183         @ Lock CPU (Disable external debug access)
 184         ldr     r6, [r0, #0x1e4] @ CPUCFG_DBG_CTL1_REG
 185         bic     r6, r6, r4
 186         str     r6, [r0, #0x1e4]
 187
 188         movw    r0, #(SUNXI_PRCM_BASE & 0xffff)
 189         movt    r0, #(SUNXI_PRCM_BASE >> 16)
 190
 191 #ifdef CONFIG_MACH_SUN6I
 192         @ Release power clamp
 193         lsl     r5, r1, #2      @ 1 register per CPU
 194         add     r5, r5, r0      @ PRCM
 195         movw    r6, #0x1ff
 196         movt    r6, #0
 197 1:      lsrs    r6, r6, #1
 198         str     r6, [r5, #0x140] @ CPUx_PWR_CLAMP
 199         bne     1b
 200 #endif
 201
 202         timer_wait r6, TEN_MS
 203
 204         @ Clear power gating
 205         ldr     r6, [r0, #0x100] @ CPU_PWROFF_GATING
 206         bic     r6, r6, r4
 207         str     r6, [r0, #0x100]
 208
 209         @ re-calculate CPU control register address
 210         movw    r0, #(SUN6I_CPUCFG_BASE & 0xffff)
 211         movt    r0, #(SUN6I_CPUCFG_BASE >> 16)
 212
 213         @ Deassert reset on target CPU
 214         mov     r6, #3
 215         lsl     r5, r1, #6      @ 64 bytes per CPU
 216         add     r5, r5, #0x40   @ Offset from base
 217         add     r5, r5, r0      @ CPU control block
 218         str     r6, [r5]
 219
 220         @ Unlock CPU (Enable external debug access)
 221         ldr     r6, [r0, #0x1e4] @ CPUCFG_DBG_CTL1_REG
 222         orr     r6, r6, r4
 223         str     r6, [r0, #0x1e4]
 224
 225         mov     r0, #ARM_PSCI_RET_SUCCESS       @ Return PSCI_RET_SUCCESS
 226         pop     {pc}
 227
 228 .globl  psci_cpu_off
 229 psci_cpu_off:
 230         bl      psci_cpu_off_common
 231
 232         @ Ask CPU0 to pull the rug...
 233         movw    r0, #(GICD_BASE & 0xffff)
 234         movt    r0, #(GICD_BASE >> 16)
 235         movw    r1, #15                         @ SGI15
 236         movt    r1, #1                          @ Target is CPU0
 237         str     r1, [r0, #GICD_SGIR]
 238         dsb
 239
 240 1:      wfi
 241         b       1b
 242
 243 .globl  psci_arch_init
 244 psci_arch_init:
 245         mov     r6, lr
 246
 247         movw    r4, #(GICD_BASE & 0xffff)
 248         movt    r4, #(GICD_BASE >> 16)
 249
 250         ldr     r5, [r4, #GICD_IGROUPRn]
 251         bic     r5, r5, #(1 << 15)      @ SGI15 as Group-0
 252         str     r5, [r4, #GICD_IGROUPRn]
 253
 254         mov     r5, #0                  @ Set SGI15 priority to 0
 255         strb    r5, [r4, #(GICD_IPRIORITYRn + 15)]
 256
 257         add     r4, r4, #0x1000         @ GICC address
 258
 259         mov     r5, #0xff
 260         str     r5, [r4, #GICC_PMR]     @ Be cool with non-secure
 261
 262         ldr     r5, [r4, #GICC_CTLR]
 263         orr     r5, r5, #(1 << 3)       @ Switch FIQEn on
 264         str     r5, [r4, #GICC_CTLR]
 265
 266         mrc     p15, 0, r5, c1, c1, 0   @ Read SCR
 267         orr     r5, r5, #4              @ Enable FIQ in monitor mode
 268         bic     r5, r5, #1              @ Secure mode
 269         mcr     p15, 0, r5, c1, c1, 0   @ Write SCR
 270         isb
 271
 272         bl      psci_get_cpu_id         @ CPU ID => r0
 273         bl      psci_get_cpu_stack_top  @ stack top => r0
 274         mov     sp, r0
 275
 276         bx      r6
 277
 278         .globl psci_text_end
 279 psci_text_end:
 280         .popsection