arch/arm/cpu/arm720t/start.S

   1 /*
   2  *  armboot - Startup Code for ARM720 CPU-core
   3  *
   4  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   5  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
   6  *
   7  * See file CREDITS for list of people who contributed to this
   8  * project.
   9  *
  10  * This program is free software; you can redistribute it and/or
  11  * modify it under the terms of the GNU General Public License as
  12  * published by the Free Software Foundation; either version 2 of
  13  * the License, or (at your option) any later version.
  14  *
  15  * This program is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  * GNU General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU General Public License
  21  * along with this program; if not, write to the Free Software
  22  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  23  * MA 02111-1307 USA
  24  */
  25
  26 #include <asm-offsets.h>
  27 #include <config.h>
  28 #include <version.h>
  29 #include <asm/hardware.h>
  30
  31 /*
  32  *************************************************************************
  33  *
  34  * Jump vector table as in table 3.1 in [1]
  35  *
  36  *************************************************************************
  37  */
  38
  39
  40 .globl _start
  41 _start: b       reset
  42         ldr     pc, _undefined_instruction
  43         ldr     pc, _software_interrupt
  44         ldr     pc, _prefetch_abort
  45         ldr     pc, _data_abort
  46         ldr     pc, _not_used
  47         ldr     pc, _irq
  48         ldr     pc, _fiq
  49
  50 #ifdef CONFIG_SPL_BUILD
  51 _undefined_instruction: .word _undefined_instruction
  52 _software_interrupt:    .word _software_interrupt
  53 _prefetch_abort:        .word _prefetch_abort
  54 _data_abort:            .word _data_abort
  55 _not_used:              .word _not_used
  56 _irq:                   .word _irq
  57 _fiq:                   .word _fiq
  58 _pad:                   .word 0x12345678 /* now 16*4=64 */
  59 #else
  60 _undefined_instruction: .word undefined_instruction
  61 _software_interrupt:    .word software_interrupt
  62 _prefetch_abort:        .word prefetch_abort
  63 _data_abort:            .word data_abort
  64 _not_used:              .word not_used
  65 _irq:                   .word irq
  66 _fiq:                   .word fiq
  67 _pad:                   .word 0x12345678 /* now 16*4=64 */
  68 #endif  /* CONFIG_SPL_BUILD */
  69
  70         .balignl 16,0xdeadbeef
  71
  72
  73 /*
  74  *************************************************************************
  75  *
  76  * Startup Code (reset vector)
  77  *
  78  * do important init only if we don't start from RAM!
  79  * relocate armboot to ram
  80  * setup stack
  81  * jump to second stage
  82  *
  83  *************************************************************************
  84  */
  85
  86 .globl _TEXT_BASE
  87 _TEXT_BASE:
  88 #if defined(CONFIG_SPL_BUILD) && defined(CONFIG_SPL_TEXT_BASE)
  89         .word   CONFIG_SPL_TEXT_BASE
  90 #else
  91         .word   CONFIG_SYS_TEXT_BASE
  92 #endif
  93
  94 /*
  95  * These are defined in the board-specific linker script.
  96  * Subtracting _start from them lets the linker put their
  97  * relative position in the executable instead of leaving
  98  * them null.
  99  */
 100 .globl _bss_start_ofs
 101 _bss_start_ofs:
 102         .word __bss_start - _start
 103
 104 .globl _bss_end_ofs
 105 _bss_end_ofs:
 106         .word __bss_end - _start
 107
 108 .globl _end_ofs
 109 _end_ofs:
 110         .word _end - _start
 111
 112 #ifdef CONFIG_USE_IRQ
 113 /* IRQ stack memory (calculated at run-time) */
 114 .globl IRQ_STACK_START
 115 IRQ_STACK_START:
 116         .word   0x0badc0de
 117
 118 /* IRQ stack memory (calculated at run-time) */
 119 .globl FIQ_STACK_START
 120 FIQ_STACK_START:
 121         .word 0x0badc0de
 122 #endif
 123
 124 /* IRQ stack memory (calculated at run-time) + 8 bytes */
 125 .globl IRQ_STACK_START_IN
 126 IRQ_STACK_START_IN:
 127         .word   0x0badc0de
 128
 129 /*
 130  * the actual reset code
 131  */
 132
 133 reset:
 134         /*
 135          * set the cpu to SVC32 mode
 136          */
 137         mrs     r0,cpsr
 138         bic     r0,r0,#0x1f
 139         orr     r0,r0,#0xd3
 140         msr     cpsr,r0
 141
 142         /*
 143          * we do sys-critical inits only at reboot,
 144          * not when booting from ram!
 145          */
 146 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 147         bl      cpu_init_crit
 148 #endif
 149
 150         bl      _main
 151
 152 /*------------------------------------------------------------------------------*/
 153
 154 /*
 155  * void relocate_code (addr_sp, gd, addr_moni)
 156  *
 157  * This function relocates the monitor code.
 158  */
 159         .globl  relocate_code
 160 relocate_code:
 161         mov     r4, r0  /* save addr_sp */
 162         mov     r5, r1  /* save addr of gd */
 163         mov     r6, r2  /* save addr of destination */
 164
 165         adr     r0, _start
 166         subs    r9, r6, r0              /* r9 <- relocation offset */
 167         beq     relocate_done           /* skip relocation */
 168         mov     r1, r6                  /* r1 <- scratch for copy_loop */
 169         ldr     r3, _bss_start_ofs
 170         add     r2, r0, r3              /* r2 <- source end address         */
 171
 172 copy_loop:
 173         ldmia   r0!, {r10-r11}          /* copy from source address [r0]    */
 174         stmia   r1!, {r10-r11}          /* copy to   target address [r1]    */
 175         cmp     r0, r2                  /* until source end address [r2]    */
 176         blo     copy_loop
 177
 178 #ifndef CONFIG_SPL_BUILD
 179         /*
 180          * fix .rel.dyn relocations
 181          */
 182         ldr     r0, _TEXT_BASE          /* r0 <- Text base */
 183         ldr     r10, _dynsym_start_ofs  /* r10 <- sym table ofs */
 184         add     r10, r10, r0            /* r10 <- sym table in FLASH */
 185         ldr     r2, _rel_dyn_start_ofs  /* r2 <- rel dyn start ofs */
 186         add     r2, r2, r0              /* r2 <- rel dyn start in FLASH */
 187         ldr     r3, _rel_dyn_end_ofs    /* r3 <- rel dyn end ofs */
 188         add     r3, r3, r0              /* r3 <- rel dyn end in FLASH */
 189 fixloop:
 190         ldr     r0, [r2]                /* r0 <- location to fix up, IN FLASH! */
 191         add     r0, r0, r9              /* r0 <- location to fix up in RAM */
 192         ldr     r1, [r2, #4]
 193         and     r7, r1, #0xff
 194         cmp     r7, #23                 /* relative fixup? */
 195         beq     fixrel
 196         cmp     r7, #2                  /* absolute fixup? */
 197         beq     fixabs
 198         /* ignore unknown type of fixup */
 199         b       fixnext
 200 fixabs:
 201         /* absolute fix: set location to (offset) symbol value */
 202         mov     r1, r1, LSR #4          /* r1 <- symbol index in .dynsym */
 203         add     r1, r10, r1             /* r1 <- address of symbol in table */
 204         ldr     r1, [r1, #4]            /* r1 <- symbol value */
 205         add     r1, r1, r9              /* r1 <- relocated sym addr */
 206         b       fixnext
 207 fixrel:
 208         /* relative fix: increase location by offset */
 209         ldr     r1, [r0]
 210         add     r1, r1, r9
 211 fixnext:
 212         str     r1, [r0]
 213         add     r2, r2, #8              /* each rel.dyn entry is 8 bytes */
 214         cmp     r2, r3
 215         blo     fixloop
 216 #endif
 217
 218 relocate_done:
 219
 220         mov     pc, lr
 221
 222 _rel_dyn_start_ofs:
 223         .word __rel_dyn_start - _start
 224 _rel_dyn_end_ofs:
 225         .word __rel_dyn_end - _start
 226 _dynsym_start_ofs:
 227         .word __dynsym_start - _start
 228
 229         .globl  c_runtime_cpu_setup
 230 c_runtime_cpu_setup:
 231
 232         mov     pc, lr
 233
 234 /*
 235  *************************************************************************
 236  *
 237  * CPU_init_critical registers
 238  *
 239  * setup important registers
 240  * setup memory timing
 241  *
 242  *************************************************************************
 243  */
 244
 245 cpu_init_crit:
 246
 247 #if !defined(CONFIG_TEGRA)
 248         mov     ip, lr
 249         /*
 250          * before relocating, we have to setup RAM timing
 251          * because memory timing is board-dependent, you will
 252          * find a lowlevel_init.S in your board directory.
 253          */
 254         bl      lowlevel_init
 255         mov     lr, ip
 256 #endif
 257
 258         mov     pc, lr
 259
 260
 261 #ifndef CONFIG_SPL_BUILD
 262 /*
 263  *************************************************************************
 264  *
 265  * Interrupt handling
 266  *
 267  *************************************************************************
 268  */
 269
 270 @
 271 @ IRQ stack frame.
 272 @
 273 #define S_FRAME_SIZE    72
 274
 275 #define S_OLD_R0        68
 276 #define S_PSR           64
 277 #define S_PC            60
 278 #define S_LR            56
 279 #define S_SP            52
 280
 281 #define S_IP            48
 282 #define S_FP            44
 283 #define S_R10           40
 284 #define S_R9            36
 285 #define S_R8            32
 286 #define S_R7            28
 287 #define S_R6            24
 288 #define S_R5            20
 289 #define S_R4            16
 290 #define S_R3            12
 291 #define S_R2            8
 292 #define S_R1            4
 293 #define S_R0            0
 294
 295 #define MODE_SVC 0x13
 296 #define I_BIT    0x80
 297
 298 /*
 299  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 300  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 301  */
 302
 303         .macro  bad_save_user_regs
 304         sub     sp, sp, #S_FRAME_SIZE
 305         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 306         add     r8, sp, #S_PC
 307
 308         ldr     r2, IRQ_STACK_START_IN
 309         ldmia   r2, {r2 - r4}                   @ get pc, cpsr, old_r0
 310         add     r0, sp, #S_FRAME_SIZE           @ restore sp_SVC
 311
 312         add     r5, sp, #S_SP
 313         mov     r1, lr
 314         stmia   r5, {r0 - r4}                   @ save sp_SVC, lr_SVC, pc, cpsr, old_r
 315         mov     r0, sp
 316         .endm
 317
 318         .macro  irq_save_user_regs
 319         sub     sp, sp, #S_FRAME_SIZE
 320         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 321         add     r8, sp, #S_PC
 322         stmdb   r8, {sp, lr}^                   @ Calling SP, LR
 323         str     lr, [r8, #0]                    @ Save calling PC
 324         mrs     r6, spsr
 325         str     r6, [r8, #4]                    @ Save CPSR
 326         str     r0, [r8, #8]                    @ Save OLD_R0
 327         mov     r0, sp
 328         .endm
 329
 330         .macro  irq_restore_user_regs
 331         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 332         mov     r0, r0
 333         ldr     lr, [sp, #S_PC]                 @ Get PC
 334         add     sp, sp, #S_FRAME_SIZE
 335         subs    pc, lr, #4                      @ return & move spsr_svc into cpsr
 336         .endm
 337
 338         .macro get_bad_stack
 339         ldr     r13, IRQ_STACK_START_IN         @ setup our mode stack
 340
 341         str     lr, [r13]                       @ save caller lr / spsr
 342         mrs     lr, spsr
 343         str     lr, [r13, #4]
 344
 345         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 346         msr     spsr_c, r13
 347         mov     lr, pc
 348         movs    pc, lr
 349         .endm
 350
 351         .macro get_irq_stack                    @ setup IRQ stack
 352         ldr     sp, IRQ_STACK_START
 353         .endm
 354
 355         .macro get_fiq_stack                    @ setup FIQ stack
 356         ldr     sp, FIQ_STACK_START
 357         .endm
 358
 359 /*
 360  * exception handlers
 361  */
 362         .align  5
 363 undefined_instruction:
 364         get_bad_stack
 365         bad_save_user_regs
 366         bl      do_undefined_instruction
 367
 368         .align  5
 369 software_interrupt:
 370         get_bad_stack
 371         bad_save_user_regs
 372         bl      do_software_interrupt
 373
 374         .align  5
 375 prefetch_abort:
 376         get_bad_stack
 377         bad_save_user_regs
 378         bl      do_prefetch_abort
 379
 380         .align  5
 381 data_abort:
 382         get_bad_stack
 383         bad_save_user_regs
 384         bl      do_data_abort
 385
 386         .align  5
 387 not_used:
 388         get_bad_stack
 389         bad_save_user_regs
 390         bl      do_not_used
 391
 392 #ifdef CONFIG_USE_IRQ
 393
 394         .align  5
 395 irq:
 396         get_irq_stack
 397         irq_save_user_regs
 398         bl      do_irq
 399         irq_restore_user_regs
 400
 401         .align  5
 402 fiq:
 403         get_fiq_stack
 404         /* someone ought to write a more effiction fiq_save_user_regs */
 405         irq_save_user_regs
 406         bl      do_fiq
 407         irq_restore_user_regs
 408
 409 #else
 410
 411         .align  5
 412 irq:
 413         get_bad_stack
 414         bad_save_user_regs
 415         bl      do_irq
 416
 417         .align  5
 418 fiq:
 419         get_bad_stack
 420         bad_save_user_regs
 421         bl      do_fiq
 422
 423 #endif
 424 #endif /* CONFIG_SPL_BUILD */