apps/makeapps.com

   1 $!
   2 $!  MAKEAPPS.COM
   3 $!  Written By:  Robert Byer
   4 $!               Vice-President
   5 $!               A-Com Computing, Inc.
   6 $!               byer@mail.all-net.net
   7 $!
   8 $!  Changes by Richard Levitte <richard@levitte.org>
   9 $!
  10 $!  This command files compiles and creates all the various different
  11 $!  "application" programs for the different types of encryption for OpenSSL.
  12 $!  The EXE's are placed in the directory [.xxx.EXE.APPS] where "xxx" denotes
  13 $!  ALPHA, IA64 or VAX, depending on your machine architecture.
  14 $!
  15 $!  It was written so it would try to determine what "C" compiler to
  16 $!  use or you can specify which "C" compiler to use.
  17 $!
  18 $!  Specify DEBUG or NODEBUG as P1 to compile with or without debugger
  19 $!  information.
  20 $!
  21 $!  Specify which compiler at P2 to try to compile under.
  22 $!
  23 $!         VAXC  For VAX C.
  24 $!         DECC  For DEC C.
  25 $!         GNUC  For GNU C.
  26 $!
  27 $!  If you don't speficy a compiler, it will try to determine which
  28 $!  "C" compiler to use.
  29 $!
  30 $!  P3, if defined, sets a TCP/IP library to use, through one of the following
  31 $!  keywords:
  32 $!
  33 $!      UCX             for UCX
  34 $!      SOCKETSHR       for SOCKETSHR+NETLIB
  35 $!      TCPIP           for TCPIP (post UCX)
  36 $!
  37 $!  P4, if defined, sets a compiler thread NOT needed on OpenVMS 7.1 (and up)
  38 $!
  39 $!  P5, if defined, sets a choice of programs to compile.
  40 $!
  41 $!
  42 $! Define A TCP/IP Library That We Will Need To Link To.
  43 $! (That Is, If We Need To Link To One.)
  44 $!
  45 $ TCPIP_LIB = ""
  46 $!
  47 $! Check What Architecture We Are Using.
  48 $!
  49 $ IF (F$GETSYI("CPU").LT.128)
  50 $ THEN
  51 $!
  52 $!  The Architecture Is VAX.
  53 $!
  54 $   ARCH := VAX
  55 $!
  56 $! Else...
  57 $!
  58 $ ELSE
  59 $!
  60 $!  The Architecture Is Alpha, IA64 or whatever comes in the future.
  61 $!
  62 $   ARCH = F$EDIT( F$GETSYI( "ARCH_NAME"), "UPCASE")
  63 $   IF (ARCH .EQS. "") THEN ARCH = "UNK"
  64 $!
  65 $! End The Architecture Check.
  66 $!
  67 $ ENDIF
  68 $!
  69 $! Define what programs should be compiled
  70 $!
  71 $ PROGRAMS := OPENSSL
  72 $!$ PROGRAMS := VERIFY,ASN1PARS,REQ,DGST,DH,ENC,PASSWD,GENDH,ERRSTR,CA,CRL,-
  73 $!            RSA,DSA,DSAPARAM,-
  74 $!            X509,GENRSA,GENDSA,S_SERVER,S_CLIENT,SPEED,-
  75 $!            S_TIME,VERSION,PKCS7,CRL2P7,SESS_ID,CIPHERS,NSEQ,
  76 $!
  77 $! Define The CRYPTO Library.
  78 $!
  79 $ CRYPTO_LIB := SYS$DISK:[-.'ARCH'.EXE.CRYPTO]LIBCRYPTO.OLB
  80 $!
  81 $! Define The SSL Library.
  82 $!
  83 $ SSL_LIB := SYS$DISK:[-.'ARCH'.EXE.SSL]LIBSSL.OLB
  84 $!
  85 $! Define The OBJ Directory.
  86 $!
  87 $ OBJ_DIR := SYS$DISK:[-.'ARCH'.OBJ.APPS]
  88 $!
  89 $! Define The EXE Directory.
  90 $!
  91 $ EXE_DIR := SYS$DISK:[-.'ARCH'.EXE.APPS]
  92 $!
  93 $! Check To Make Sure We Have Valid Command Line Parameters.
  94 $!
  95 $ GOSUB CHECK_OPTIONS
  96 $!
  97 $! Initialise logical names and such
  98 $!
  99 $ GOSUB INITIALISE
 100 $!
 101 $! Tell The User What Kind of Machine We Run On.
 102 $!
 103 $ WRITE SYS$OUTPUT "Compiling On A ",ARCH," Machine."
 104 $!
 105 $! Check To See If The OBJ Directory Exists.
 106 $!
 107 $ IF (F$PARSE(OBJ_DIR).EQS."")
 108 $ THEN
 109 $!
 110 $!  It Dosen't Exist, So Create It.
 111 $!
 112 $   CREATE/DIRECTORY 'OBJ_DIR'
 113 $!
 114 $! End The OBJ Directory Check.
 115 $!
 116 $ ENDIF
 117 $!
 118 $! Check To See If The EXE Directory Exists.
 119 $!
 120 $ IF (F$PARSE(EXE_DIR).EQS."")
 121 $ THEN
 122 $!
 123 $!  It Dosen't Exist, So Create It.
 124 $!
 125 $   CREATE/DIRECTORY 'EXE_DIR'
 126 $!
 127 $! End The EXE Directory Check.
 128 $!
 129 $ ENDIF
 130 $!
 131 $! Check To See If We Have The Proper Libraries.
 132 $!
 133 $ GOSUB LIB_CHECK
 134 $!
 135 $! Check To See If We Have A Linker Option File.
 136 $!
 137 $ GOSUB CHECK_OPT_FILE
 138 $!
 139 $! Define The Application Files.
 140 $! NOTE: Some might think this list ugly.  However, it's made this way to
 141 $! reflect the E_OBJ variable in Makefile as closely as possible, thereby
 142 $! making it fairly easy to verify that the lists are the same.
 143 $!
 144 $ LIB_FILES = "VERIFY;ASN1PARS;REQ;DGST;DH;DHPARAM;ENC;PASSWD;GENDH;ERRSTR;"+-
 145               "CA;PKCS7;CRL2P7;CRL;"+-
 146               "RSA;RSAUTL;DSA;DSAPARAM;EC;ECPARAM;"+-
 147               "X509;GENRSA;GENDSA;S_SERVER;S_CLIENT;SPEED;"+-
 148               "S_TIME;APPS;S_CB;S_SOCKET;APP_RAND;VERSION;SESS_ID;"+-
 149               "CIPHERS;NSEQ;PKCS12;PKCS8;SPKAC;SMIME;RAND;ENGINE;OCSP;PRIME"
 150 $ TCPIP_PROGRAMS = ",,"
 151 $ IF COMPILER .EQS. "VAXC" THEN -
 152      TCPIP_PROGRAMS = ",OPENSSL,"
 153 $!
 154 $! Setup exceptional compilations
 155 $!
 156 $ COMPILEWITH_CC2 = ",S_SERVER,S_CLIENT,"
 157 $!
 158 $ PHASE := LIB
 159 $!
 160 $ RESTART:
 161 $!
 162 $!  Define A File Counter And Set It To "0".
 163 $!
 164 $ FILE_COUNTER = 0
 165 $!
 166 $! Top Of The File Loop.
 167 $!
 168 $ NEXT_FILE:
 169 $!
 170 $! O.K, Extract The File Name From The File List.
 171 $!
 172 $ FILE_NAME0 = F$EDIT(F$ELEMENT(FILE_COUNTER,";",'PHASE'_FILES),"TRIM")
 173 $ FILE_NAME = F$EDIT(F$ELEMENT(0,",",FILE_NAME0),"TRIM")
 174 $ EXTRA_OBJ = FILE_NAME0 - FILE_NAME
 175 $!
 176 $! Check To See If We Are At The End Of The File List.
 177 $!
 178 $ IF (FILE_NAME0.EQS.";")
 179 $ THEN
 180 $   IF (PHASE.EQS."LIB")
 181 $   THEN
 182 $     PHASE := APP
 183 $     GOTO RESTART
 184 $   ELSE
 185 $     GOTO FILE_DONE
 186 $   ENDIF
 187 $ ENDIF
 188 $!
 189 $! Increment The Counter.
 190 $!
 191 $ FILE_COUNTER = FILE_COUNTER + 1
 192 $!
 193 $! Check to see if this program should actually be compiled
 194 $!
 195 $ IF PHASE .EQS. "APP" .AND. -
 196      ","+PROGRAMS+"," - (","+F$EDIT(FILE_NAME,"UPCASE")+",") .EQS. ","+PROGRAMS+","
 197 $ THEN
 198 $   GOTO NEXT_FILE
 199 $ ENDIF
 200 $!
 201 $! Create The Source File Name.
 202 $!
 203 $ SOURCE_FILE = "SYS$DISK:[]" + FILE_NAME + ".C"
 204 $!
 205 $! Create The Object File Name.
 206 $!
 207 $ OBJECT_FILE = OBJ_DIR + FILE_NAME + ".OBJ"
 208 $!
 209 $! Create The Executable File Name.
 210 $!
 211 $ EXE_FILE = EXE_DIR + FILE_NAME + ".EXE"
 212 $ ON WARNING THEN GOTO NEXT_FILE
 213 $!
 214 $! Check To See If The File We Want To Compile Actually Exists.
 215 $!
 216 $ IF (F$SEARCH(SOURCE_FILE).EQS."")
 217 $ THEN
 218 $!
 219 $!  Tell The User That The File Dosen't Exist.
 220 $!
 221 $   WRITE SYS$OUTPUT ""
 222 $   WRITE SYS$OUTPUT "The File ",SOURCE_FILE," Dosen't Exist."
 223 $   WRITE SYS$OUTPUT ""
 224 $!
 225 $!  Exit The Build.
 226 $!
 227 $   GOTO EXIT
 228 $!
 229 $! End The File Exist Check.
 230 $!
 231 $ ENDIF
 232 $!
 233 $! Tell The User What We Are Building.
 234 $!
 235 $ IF (PHASE.EQS."LIB")
 236 $ THEN
 237 $   WRITE SYS$OUTPUT "Compiling The ",FILE_NAME,".C File."
 238 $ ELSE
 239 $   WRITE SYS$OUTPUT "Building The ",FILE_NAME," Application Program."
 240 $ ENDIF
 241 $!
 242 $! Compile The File.
 243 $!
 244 $ ON ERROR THEN GOTO NEXT_FILE
 245 $ IF COMPILEWITH_CC2 - FILE_NAME .NES. COMPILEWITH_CC2
 246 $ THEN
 247 $   CC2/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 248 $ ELSE
 249 $   CC/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 250 $ ENDIF
 251 $!
 252 $ ON WARNING THEN GOTO NEXT_FILE
 253 $!
 254 $ IF (PHASE.EQS."LIB")
 255 $ THEN
 256 $   GOTO NEXT_FILE
 257 $ ENDIF
 258 $!
 259 $!  Check if this program works well without a TCPIP library
 260 $!
 261 $ IF TCPIP_LIB .EQS. "" .AND. TCPIP_PROGRAMS - FILE_NAME .NES. TCPIP_PROGRAMS
 262 $ THEN
 263 $   WRITE SYS$OUTPUT FILE_NAME," needs a TCP/IP library.  Can't link.  Skipping..."
 264 $   GOTO NEXT_FILE
 265 $ ENDIF
 266 $!
 267 $! Link The Program.
 268 $! Check To See If We Are To Link With A Specific TCP/IP Library.
 269 $!
 270 $ IF (TCPIP_LIB.NES."")
 271 $ THEN
 272 $!
 273 $! Don't Link With The RSAREF Routines And TCP/IP Library.
 274 $!
 275 $   LINK/'DEBUGGER'/'TRACEBACK' /EXE='EXE_FILE' -
 276         'OBJECT_FILE''EXTRA_OBJ', -
 277         'SSL_LIB'/LIBRARY,'CRYPTO_LIB'/LIBRARY, -
 278         'TCPIP_LIB','OPT_FILE'/OPTION
 279 $!
 280 $! Else...
 281 $!
 282 $ ELSE
 283 $!
 284 $! Don't Link With The RSAREF Routines And Link With A TCP/IP Library.
 285 $!
 286 $   LINK/'DEBUGGER'/'TRACEBACK' /EXE='EXE_FILE' -
 287         'OBJECT_FILE''EXTRA_OBJ', -
 288         'SSL_LIB'/LIBRARY,'CRYPTO_LIB'/LIBRARY, -
 289         'OPT_FILE'/OPTION
 290 $!
 291 $! End The TCP/IP Library Check.
 292 $!
 293 $ ENDIF
 294 $!
 295 $! Go Back And Do It Again.
 296 $!
 297 $ GOTO NEXT_FILE
 298 $!
 299 $! All Done With This File.
 300 $!
 301 $ FILE_DONE:
 302 $ EXIT:
 303 $!
 304 $! All Done, Time To Clean Up And Exit.
 305 $!
 306 $ GOSUB CLEANUP
 307 $ EXIT
 308 $!
 309 $! Check For The Link Option FIle.
 310 $!
 311 $ CHECK_OPT_FILE:
 312 $!
 313 $! Check To See If We Need To Make A VAX C Option File.
 314 $!
 315 $ IF (COMPILER.EQS."VAXC")
 316 $ THEN
 317 $!
 318 $!  Check To See If We Already Have A VAX C Linker Option File.
 319 $!
 320 $   IF (F$SEARCH(OPT_FILE).EQS."")
 321 $   THEN
 322 $!
 323 $!    We Need A VAX C Linker Option File.
 324 $!
 325 $     CREATE 'OPT_FILE'
 326 $DECK
 327 !
 328 ! Default System Options File To Link Agianst
 329 ! The Sharable VAX C Runtime Library.
 330 !
 331 SYS$SHARE:VAXCRTL.EXE/SHARE
 332 $EOD
 333 $!
 334 $!  End The Option File Check.
 335 $!
 336 $   ENDIF
 337 $!
 338 $! End The VAXC Check.
 339 $!
 340 $ ENDIF
 341 $!
 342 $! Check To See If We Need A GNU C Option File.
 343 $!
 344 $ IF (COMPILER.EQS."GNUC")
 345 $ THEN
 346 $!
 347 $!  Check To See If We Already Have A GNU C Linker Option File.
 348 $!
 349 $   IF (F$SEARCH(OPT_FILE).EQS."")
 350 $   THEN
 351 $!
 352 $!    We Need A GNU C Linker Option File.
 353 $!
 354 $     CREATE 'OPT_FILE'
 355 $DECK
 356 !
 357 ! Default System Options File To Link Agianst
 358 ! The Sharable C Runtime Library.
 359 !
 360 GNU_CC:[000000]GCCLIB/LIBRARY
 361 SYS$SHARE:VAXCRTL/SHARE
 362 $EOD
 363 $!
 364 $!  End The Option File Check.
 365 $!
 366 $   ENDIF
 367 $!
 368 $! End The GNU C Check.
 369 $!
 370 $ ENDIF
 371 $!
 372 $! Check To See If We Need A DEC C Option File.
 373 $!
 374 $ IF (COMPILER.EQS."DECC")
 375 $ THEN
 376 $!
 377 $!  Check To See If We Already Have A DEC C Linker Option File.
 378 $!
 379 $   IF (F$SEARCH(OPT_FILE).EQS."")
 380 $   THEN
 381 $!
 382 $!    Figure Out If We Need An AXP Or A VAX Linker Option File.
 383 $!
 384 $     IF ARCH.EQS."VAX"
 385 $     THEN
 386 $!
 387 $!      We Need A DEC C Linker Option File For VAX.
 388 $!
 389 $       CREATE 'OPT_FILE'
 390 $DECK
 391 !
 392 ! Default System Options File To Link Agianst
 393 ! The Sharable DEC C Runtime Library.
 394 !
 395 SYS$SHARE:DECC$SHR.EXE/SHARE
 396 $EOD
 397 $!
 398 $!    Else...
 399 $!
 400 $     ELSE
 401 $!
 402 $!      Create The non-VAX Linker Option File.
 403 $!
 404 $       CREATE 'OPT_FILE'
 405 $DECK
 406 !
 407 ! Default System Options File For non-VAX To Link Agianst
 408 ! The Sharable C Runtime Library.
 409 !
 410 SYS$SHARE:CMA$OPEN_LIB_SHR/SHARE
 411 SYS$SHARE:CMA$OPEN_RTL/SHARE
 412 $EOD
 413 $!
 414 $!    End The DEC C Option File Check.
 415 $!
 416 $     ENDIF
 417 $!
 418 $!  End The Option File Search.
 419 $!
 420 $   ENDIF
 421 $!
 422 $! End The DEC C Check.
 423 $!
 424 $ ENDIF
 425 $!
 426 $!  Tell The User What Linker Option File We Are Using.
 427 $!
 428 $ WRITE SYS$OUTPUT "Using Linker Option File ",OPT_FILE,"."
 429 $!
 430 $! Time To RETURN.
 431 $!
 432 $ RETURN
 433 $!
 434 $! Check To See If We Have The Appropiate Libraries.
 435 $!
 436 $ LIB_CHECK:
 437 $!
 438 $! Look For The Library LIBCRYPTO.OLB.
 439 $!
 440 $ IF (F$SEARCH(CRYPTO_LIB).EQS."")
 441 $ THEN
 442 $!
 443 $!  Tell The User We Can't Find The LIBCRYPTO.OLB Library.
 444 $!
 445 $   WRITE SYS$OUTPUT ""
 446 $   WRITE SYS$OUTPUT "Can't Find The Library ",CRYPTO_LIB,"."
 447 $   WRITE SYS$OUTPUT "We Can't Link Without It."
 448 $   WRITE SYS$OUTPUT ""
 449 $!
 450 $!  Since We Can't Link Without It, Exit.
 451 $!
 452 $   EXIT
 453 $!
 454 $! End The Crypto Library Check.
 455 $!
 456 $ ENDIF
 457 $!
 458 $! Look For The Library LIBSSL.OLB.
 459 $!
 460 $ IF (F$SEARCH(SSL_LIB).EQS."")
 461 $ THEN
 462 $!
 463 $!  Tell The User We Can't Find The LIBSSL.OLB Library.
 464 $!
 465 $   WRITE SYS$OUTPUT ""
 466 $   WRITE SYS$OUTPUT "Can't Find The Library ",SSL_LIB,"."
 467 $   WRITE SYS$OUTPUT "Some Of The Test Programs Need To Link To It."
 468 $   WRITE SYS$OUTPUT ""
 469 $!
 470 $!  Since We Can't Link Without It, Exit.
 471 $!
 472 $   EXIT
 473 $!
 474 $! End The SSL Library Check.
 475 $!
 476 $ ENDIF
 477 $!
 478 $! Time To Return.
 479 $!
 480 $ RETURN
 481 $!
 482 $! Check The User's Options.
 483 $!
 484 $ CHECK_OPTIONS:
 485 $!
 486 $! Check To See If P1 Is Blank.
 487 $!
 488 $ IF (P1.EQS."NODEBUG")
 489 $ THEN
 490 $!
 491 $!   P1 Is NODEBUG, So Compile Without Debugger Information.
 492 $!
 493 $    DEBUGGER  = "NODEBUG"
 494 $    TRACEBACK = "NOTRACEBACK"
 495 $    GCC_OPTIMIZE = "OPTIMIZE"
 496 $    CC_OPTIMIZE = "OPTIMIZE"
 497 $    WRITE SYS$OUTPUT "No Debugger Information Will Be Produced During Compile."
 498 $    WRITE SYS$OUTPUT "Compiling With Compiler Optimization."
 499 $!
 500 $! Else...
 501 $!
 502 $ ELSE
 503 $!
 504 $!  Check To See If We Are To Compile With Debugger Information.
 505 $!
 506 $   IF (P1.EQS."DEBUG")
 507 $   THEN
 508 $!
 509 $!    Compile With Debugger Information.
 510 $!
 511 $     DEBUGGER  = "DEBUG"
 512 $     TRACEBACK = "TRACEBACK"
 513 $     GCC_OPTIMIZE = "NOOPTIMIZE"
 514 $     CC_OPTIMIZE = "NOOPTIMIZE"
 515 $     WRITE SYS$OUTPUT "Debugger Information Will Be Produced During Compile."
 516 $     WRITE SYS$OUTPUT "Compiling Without Compiler Optimization."
 517 $   ELSE
 518 $!
 519 $!    Tell The User Entered An Invalid Option..
 520 $!
 521 $     WRITE SYS$OUTPUT ""
 522 $     WRITE SYS$OUTPUT "The Option ",P1," Is Invalid.  The Valid Options Are:"
 523 $     WRITE SYS$OUTPUT ""
 524 $     WRITE SYS$OUTPUT "    DEBUG    :  Compile With The Debugger Information."
 525 $     WRITE SYS$OUTPUT "    NODEBUG  :  Compile Without The Debugger Information."
 526 $     WRITE SYS$OUTPUT ""
 527 $!
 528 $!    Time To EXIT.
 529 $!
 530 $     EXIT
 531 $!
 532 $!  End The Valid Arguement Check.
 533 $!
 534 $   ENDIF
 535 $!
 536 $! End The P1 Check.
 537 $!
 538 $ ENDIF
 539 $!
 540 $! Check To See If P2 Is Blank.
 541 $!
 542 $ IF (P2.EQS."")
 543 $ THEN
 544 $!
 545 $!  O.K., The User Didn't Specify A Compiler, Let's Try To
 546 $!  Find Out Which One To Use.
 547 $!
 548 $!  Check To See If We Have GNU C.
 549 $!
 550 $   IF (F$TRNLNM("GNU_CC").NES."")
 551 $   THEN
 552 $!
 553 $!    Looks Like GNUC, Set To Use GNUC.
 554 $!
 555 $     P2 = "GNUC"
 556 $!
 557 $!  Else...
 558 $!
 559 $   ELSE
 560 $!
 561 $!  Check To See If We Have VAXC Or DECC.
 562 $!
 563 $     IF (ARCH.NES."VAX").OR.(F$TRNLNM("DECC$CC_DEFAULT").NES."")
 564 $     THEN
 565 $!
 566 $!      Looks Like DECC, Set To Use DECC.
 567 $!
 568 $       P2 = "DECC"
 569 $!
 570 $!    Else...
 571 $!
 572 $     ELSE
 573 $!
 574 $!      Looks Like VAXC, Set To Use VAXC.
 575 $!
 576 $       P2 = "VAXC"
 577 $!
 578 $!    End The VAXC Compiler Check.
 579 $!
 580 $     ENDIF
 581 $!
 582 $!  End The DECC & VAXC Compiler Check.
 583 $!
 584 $   ENDIF
 585 $!
 586 $!  End The Compiler Check.
 587 $!
 588 $ ENDIF
 589 $!
 590 $! Check To See If We Have A Option For P3.
 591 $!
 592 $ IF (P3.EQS."")
 593 $ THEN
 594 $!
 595 $!  Find out what socket library we have available
 596 $!
 597 $   IF F$PARSE("SOCKETSHR:") .NES. ""
 598 $   THEN
 599 $!
 600 $!    We have SOCKETSHR, and it is my opinion that it's the best to use.
 601 $!
 602 $     P3 = "SOCKETSHR"
 603 $!
 604 $!    Tell the user
 605 $!
 606 $     WRITE SYS$OUTPUT "Using SOCKETSHR for TCP/IP"
 607 $!
 608 $!    Else, let's look for something else
 609 $!
 610 $   ELSE
 611 $!
 612 $!    Like UCX (the reason to do this before Multinet is that the UCX
 613 $!    emulation is easier to use...)
 614 $!
 615 $     IF F$TRNLNM("UCX$IPC_SHR") .NES. "" -
 616          .OR. F$PARSE("SYS$SHARE:UCX$IPC_SHR.EXE") .NES. "" -
 617          .OR. F$PARSE("SYS$LIBRARY:UCX$IPC.OLB") .NES. ""
 618 $     THEN
 619 $!
 620 $!      Last resort: a UCX or UCX-compatible library
 621 $!
 622 $       P3 = "UCX"
 623 $!
 624 $!      Tell the user
 625 $!
 626 $       WRITE SYS$OUTPUT "Using UCX or an emulation thereof for TCP/IP"
 627 $!
 628 $!      That was all...
 629 $!
 630 $     ENDIF
 631 $   ENDIF
 632 $ ENDIF
 633 $!
 634 $! Set Up Initial CC Definitions, Possibly With User Ones
 635 $!
 636 $ CCDEFS = "MONOLITH"
 637 $ IF F$TYPE(USER_CCDEFS) .NES. "" THEN CCDEFS = CCDEFS + "," + USER_CCDEFS
 638 $ CCEXTRAFLAGS = ""
 639 $ IF F$TYPE(USER_CCFLAGS) .NES. "" THEN CCEXTRAFLAGS = USER_CCFLAGS
 640 $ CCDISABLEWARNINGS = "LONGLONGTYPE,LONGLONGSUFX,FOUNDCR"
 641 $ IF F$TYPE(USER_CCDISABLEWARNINGS) .NES. "" THEN -
 642         CCDISABLEWARNINGS = CCDISABLEWARNINGS + "," + USER_CCDISABLEWARNINGS
 643 $!
 644 $!  Check To See If The User Entered A Valid Paramter.
 645 $!
 646 $ IF (P2.EQS."VAXC").OR.(P2.EQS."DECC").OR.(P2.EQS."GNUC")
 647 $ THEN
 648 $!
 649 $!  Check To See If The User Wanted DECC.
 650 $!
 651 $   IF (P2.EQS."DECC")
 652 $   THEN
 653 $!
 654 $!    Looks Like DECC, Set To Use DECC.
 655 $!
 656 $     COMPILER = "DECC"
 657 $!
 658 $!    Tell The User We Are Using DECC.
 659 $!
 660 $     WRITE SYS$OUTPUT "Using DECC 'C' Compiler."
 661 $!
 662 $!    Use DECC...
 663 $!
 664 $     CC = "CC"
 665 $     IF ARCH.EQS."VAX" .AND. F$TRNLNM("DECC$CC_DEFAULT").NES."/DECC" -
 666          THEN CC = "CC/DECC"
 667 $     CC = CC + "/''CC_OPTIMIZE'/''DEBUGGER'/STANDARD=ANSI89" + -
 668            "/NOLIST/PREFIX=ALL" + -
 669            "/INCLUDE=(SYS$DISK:[-],SYS$DISK:[-.CRYPTO])" + CCEXTRAFLAGS
 670 $!
 671 $!    Define The Linker Options File Name.
 672 $!
 673 $     OPT_FILE = "''EXE_DIR'VAX_DECC_OPTIONS.OPT"
 674 $!
 675 $!  End DECC Check.
 676 $!
 677 $   ENDIF
 678 $!
 679 $!  Check To See If We Are To Use VAXC.
 680 $!
 681 $   IF (P2.EQS."VAXC")
 682 $   THEN
 683 $!
 684 $!    Looks Like VAXC, Set To Use VAXC.
 685 $!
 686 $     COMPILER = "VAXC"
 687 $!
 688 $!    Tell The User We Are Using VAX C.
 689 $     WRITE SYS$OUTPUT "Using VAXC 'C' Compiler."
 690 $!
 691 $!    Compile Using VAXC.
 692 $!
 693 $     CC = "CC"
 694 $     IF ARCH.NES."VAX"
 695 $     THEN
 696 $       WRITE SYS$OUTPUT "There is no VAX C on ''ARCH'!"
 697 $       EXIT
 698 $     ENDIF
 699 $     IF F$TRNLNM("DECC$CC_DEFAULT").EQS."/DECC" THEN CC = "CC/VAXC"
 700 $     CC = CC + "/''CC_OPTIMIZE'/''DEBUGGER'/NOLIST" + -
 701            "/INCLUDE=(SYS$DISK:[-],SYS$DISK:[-.CRYPTO])" + CCEXTRAFLAGS
 702 $     CCDEFS = CCDEFS + ",""VAXC"""
 703 $!
 704 $!    Define <sys> As SYS$COMMON:[SYSLIB]
 705 $!
 706 $     DEFINE/NOLOG SYS SYS$COMMON:[SYSLIB]
 707 $!
 708 $!    Define The Linker Options File Name.
 709 $!
 710 $     OPT_FILE = "''EXE_DIR'VAX_VAXC_OPTIONS.OPT"
 711 $!
 712 $!  End VAXC Check
 713 $!
 714 $   ENDIF
 715 $!
 716 $!  Check To See If We Are To Use GNU C.
 717 $!
 718 $   IF (P2.EQS."GNUC")
 719 $   THEN
 720 $!
 721 $!    Looks Like GNUC, Set To Use GNUC.
 722 $!
 723 $     COMPILER = "GNUC"
 724 $!
 725 $!    Tell The User We Are Using GNUC.
 726 $!
 727 $     WRITE SYS$OUTPUT "Using GNU 'C' Compiler."
 728 $!
 729 $!    Use GNU C...
 730 $!
 731 $     IF F$TYPE(GCC) .EQS. "" THEN GCC := GCC
 732 $     CC = GCC+"/NOCASE_HACK/''GCC_OPTIMIZE'/''DEBUGGER'/NOLIST" + -
 733            "/INCLUDE=(SYS$DISK:[-],SYS$DISK:[-.CRYPTO])" + CCEXTRAFLAGS
 734 $!
 735 $!    Define The Linker Options File Name.
 736 $!
 737 $     OPT_FILE = "''EXE_DIR'VAX_GNUC_OPTIONS.OPT"
 738 $!
 739 $!  End The GNU C Check.
 740 $!
 741 $   ENDIF
 742 $!
 743 $!  Set up default defines
 744 $!
 745 $   CCDEFS = """FLAT_INC=1""," + CCDEFS
 746 $!
 747 $!  Else The User Entered An Invalid Arguement.
 748 $!
 749 $ ELSE
 750 $!
 751 $!  Tell The User We Don't Know What They Want.
 752 $!
 753 $   WRITE SYS$OUTPUT ""
 754 $   WRITE SYS$OUTPUT "The Option ",P2," Is Invalid.  The Valid Options Are:"
 755 $   WRITE SYS$OUTPUT ""
 756 $   WRITE SYS$OUTPUT "    VAXC  :  To Compile With VAX C."
 757 $   WRITE SYS$OUTPUT "    DECC  :  To Compile With DEC C."
 758 $   WRITE SYS$OUTPUT "    GNUC  :  To Compile With GNU C."
 759 $   WRITE SYS$OUTPUT ""
 760 $!
 761 $!  Time To EXIT.
 762 $!
 763 $   EXIT
 764 $ ENDIF
 765 $!
 766 $! Time to check the contents, and to make sure we get the correct library.
 767 $!
 768 $ IF P3.EQS."SOCKETSHR" .OR. P3.EQS."MULTINET" .OR. P3.EQS."UCX" -
 769      .OR. P3.EQS."TCPIP" .OR. P3.EQS."NONE"
 770 $ THEN
 771 $!
 772 $!  Check to see if SOCKETSHR was chosen
 773 $!
 774 $   IF P3.EQS."SOCKETSHR"
 775 $   THEN
 776 $!
 777 $!    Set the library to use SOCKETSHR
 778 $!
 779 $     TCPIP_LIB = "SYS$DISK:[-.VMS]SOCKETSHR_SHR.OPT/OPT"
 780 $!
 781 $!    Done with SOCKETSHR
 782 $!
 783 $   ENDIF
 784 $!
 785 $!  Check to see if MULTINET was chosen
 786 $!
 787 $   IF P3.EQS."MULTINET"
 788 $   THEN
 789 $!
 790 $!    Set the library to use UCX emulation.
 791 $!
 792 $     P3 = "UCX"
 793 $!
 794 $!    Done with MULTINET
 795 $!
 796 $   ENDIF
 797 $!
 798 $!  Check to see if UCX was chosen
 799 $!
 800 $   IF P3.EQS."UCX"
 801 $   THEN
 802 $!
 803 $!    Set the library to use UCX.
 804 $!
 805 $     TCPIP_LIB = "SYS$DISK:[-.VMS]UCX_SHR_DECC.OPT/OPT"
 806 $     IF F$TRNLNM("UCX$IPC_SHR") .NES. ""
 807 $     THEN
 808 $       TCPIP_LIB = "SYS$DISK:[-.VMS]UCX_SHR_DECC_LOG.OPT/OPT"
 809 $     ELSE
 810 $       IF COMPILER .NES. "DECC" .AND. ARCH .EQS. "VAX" THEN -
 811           TCPIP_LIB = "SYS$DISK:[-.VMS]UCX_SHR_VAXC.OPT/OPT"
 812 $     ENDIF
 813 $!
 814 $!    Done with UCX
 815 $!
 816 $   ENDIF
 817 $!
 818 $!  Check to see if TCPIP (post UCX) was chosen
 819 $!
 820 $   IF P3.EQS."TCPIP"
 821 $   THEN
 822 $!
 823 $!    Set the library to use TCPIP.
 824 $!
 825 $     TCPIP_LIB = "SYS$DISK:[-.VMS]TCPIP_SHR_DECC.OPT/OPT"
 826 $!
 827 $!    Done with TCPIP
 828 $!
 829 $   ENDIF
 830 $!
 831 $!  Check to see if NONE was chosen
 832 $!
 833 $   IF P3.EQS."NONE"
 834 $   THEN
 835 $!
 836 $!    Do not use TCPIP.
 837 $!
 838 $     TCPIP_LIB = ""
 839 $!
 840 $!    Done with TCPIP
 841 $!
 842 $   ENDIF
 843 $!
 844 $!  Add TCP/IP type to CC definitions.
 845 $!
 846 $   CCDEFS = CCDEFS + ",TCPIP_TYPE_''P3'"
 847 $!
 848 $!  Print info
 849 $!
 850 $   WRITE SYS$OUTPUT "TCP/IP library spec: ", TCPIP_LIB
 851 $!
 852 $!  Else The User Entered An Invalid Arguement.
 853 $!
 854 $ ELSE
 855 $!
 856 $!  Tell The User We Don't Know What They Want.
 857 $!
 858 $   WRITE SYS$OUTPUT ""
 859 $   WRITE SYS$OUTPUT "The Option ",P3," Is Invalid.  The Valid Options Are:"
 860 $   WRITE SYS$OUTPUT ""
 861 $   WRITE SYS$OUTPUT "    SOCKETSHR  :  To link with SOCKETSHR TCP/IP library."
 862 $   WRITE SYS$OUTPUT "    UCX        :  To link with UCX TCP/IP library."
 863 $   WRITE SYS$OUTPUT "    TCPIP      :  To link with TCPIP (post UCX) TCP/IP library."
 864 $   WRITE SYS$OUTPUT ""
 865 $!
 866 $!  Time To EXIT.
 867 $!
 868 $   EXIT
 869 $!
 870 $!  Done with TCP/IP libraries
 871 $!
 872 $ ENDIF
 873 $!
 874 $! Finish up the definition of CC.
 875 $!
 876 $ IF COMPILER .EQS. "DECC"
 877 $ THEN
 878 $   IF CCDISABLEWARNINGS .NES. ""
 879 $   THEN
 880 $     CCDISABLEWARNINGS = "/WARNING=(DISABLE=(" + CCDISABLEWARNINGS + "))"
 881 $   ENDIF
 882 $ ELSE
 883 $   CCDISABLEWARNINGS = ""
 884 $ ENDIF
 885 $ CC2 = CC + "/DEFINE=(" + CCDEFS + ",_POSIX_C_SOURCE)" + CCDISABLEWARNINGS
 886 $ CC = CC + "/DEFINE=(" + CCDEFS + ")" + CCDISABLEWARNINGS
 887 $!
 888 $! Show user the result
 889 $!
 890 $ WRITE/SYMBOL SYS$OUTPUT "Main Compiling Command: ",CC
 891 $!
 892 $! Special Threads For OpenVMS v7.1 Or Later
 893 $!
 894 $! Written By:  Richard Levitte
 895 $!              richard@levitte.org
 896 $!
 897 $!
 898 $! Check To See If We Have A Option For P4.
 899 $!
 900 $ IF (P4.EQS."")
 901 $ THEN
 902 $!
 903 $!  Get The Version Of VMS We Are Using.
 904 $!
 905 $   ISSEVEN :=
 906 $   TMP = F$ELEMENT(0,"-",F$EXTRACT(1,4,F$GETSYI("VERSION")))
 907 $   TMP = F$INTEGER(F$ELEMENT(0,".",TMP)+F$ELEMENT(1,".",TMP))
 908 $!
 909 $!  Check To See If The VMS Version Is v7.1 Or Later.
 910 $!
 911 $   IF (TMP.GE.71)
 912 $   THEN
 913 $!
 914 $!    We Have OpenVMS v7.1 Or Later, So Use The Special Threads.
 915 $!
 916 $     ISSEVEN := ,PTHREAD_USE_D4
 917 $!
 918 $!  End The VMS Version Check.
 919 $!
 920 $   ENDIF
 921 $!
 922 $! End The P4 Check.
 923 $!
 924 $ ENDIF
 925 $!
 926 $! Check if the user wanted to compile just a subset of all the programs.
 927 $!
 928 $ IF P5 .NES. ""
 929 $ THEN
 930 $   PROGRAMS = P5
 931 $ ENDIF
 932 $!
 933 $!  Time To RETURN...
 934 $!
 935 $ RETURN
 936 $!
 937 $ INITIALISE:
 938 $!
 939 $! Save old value of the logical name OPENSSL
 940 $!
 941 $ __SAVE_OPENSSL = F$TRNLNM("OPENSSL","LNM$PROCESS_TABLE")
 942 $!
 943 $! Save directory information
 944 $!
 945 $ __HERE = F$PARSE(F$PARSE("A.;",F$ENVIRONMENT("PROCEDURE"))-"A.;","[]A.;") - "A.;"
 946 $ __HERE = F$EDIT(__HERE,"UPCASE")
 947 $ __TOP = __HERE - "APPS]"
 948 $ __INCLUDE = __TOP + "INCLUDE.OPENSSL]"
 949 $!
 950 $! Set up the logical name OPENSSL to point at the include directory
 951 $!
 952 $ DEFINE OPENSSL/NOLOG '__INCLUDE'
 953 $!
 954 $! Done
 955 $!
 956 $ RETURN
 957 $!
 958 $ CLEANUP:
 959 $!
 960 $! Restore the logical name OPENSSL if it had a value
 961 $!
 962 $ IF __SAVE_OPENSSL .EQS. ""
 963 $ THEN
 964 $   DEASSIGN OPENSSL
 965 $ ELSE
 966 $   DEFINE/NOLOG OPENSSL '__SAVE_OPENSSL'
 967 $ ENDIF
 968 $!
 969 $! Done
 970 $!
 971 $ RETURN