CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2 if(${CMAKE_VERSION} STREQUAL "2.8.2")
   3   # bug http://vtk.org/Bug/view.php?id=11020
   4   message( WARNING "CMake/CPack version 2.8.2 will not create working .deb packages!")
   5 endif(${CMAKE_VERSION} STREQUAL "2.8.2")
   6
   7 # This can be read from ${PROJECT_NAME} after project() is called
   8 project(minetest)
   9
  10 set(VERSION_EXTRA "" CACHE STRING "Stuff to append to version string")
  11
  12 # Also remember to set PROTOCOL_VERSION in clientserver.h when releasing
  13 set(VERSION_MAJOR 0)
  14 set(VERSION_MINOR 4)
  15 set(VERSION_PATCH 12)
  16 set(VERSION_PATCH_ORIG ${VERSION_PATCH})
  17
  18 if(VERSION_EXTRA)
  19         set(VERSION_PATCH ${VERSION_PATCH}-${VERSION_EXTRA})
  20 else()
  21         # Comment the following line during release
  22         set(VERSION_PATCH ${VERSION_PATCH}-dev)
  23 endif()
  24 set(VERSION_STRING "${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH}")
  25
  26 MESSAGE(STATUS "*** Will build version ${VERSION_STRING} ***")
  27
  28 # Configuration options
  29
  30 if(WIN32)
  31         set(RUN_IN_PLACE 1 CACHE BOOL "Run directly in source directory structure")
  32 else()
  33         set(RUN_IN_PLACE 0 CACHE BOOL "Run directly in source directory structure")
  34 endif()
  35
  36 # RUN_IN_PLACE is exported as a #define value, ensure it's 1/0 instead of ON/OFF
  37 if(RUN_IN_PLACE)
  38         set(RUN_IN_PLACE 1)
  39 else()
  40         set(RUN_IN_PLACE 0)
  41 endif()
  42
  43 set(BUILD_CLIENT 1 CACHE BOOL "Build client")
  44 if(WIN32 OR APPLE)
  45         set(BUILD_SERVER 0 CACHE BOOL "Build server")
  46 else()
  47         set(BUILD_SERVER 1 CACHE BOOL "Build server")
  48 endif()
  49
  50 set(WARN_ALL 1 CACHE BOOL "Enable -Wall for Release build")
  51
  52 if(NOT CMAKE_BUILD_TYPE)
  53         # Default to release
  54         set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type: Debug or Release" FORCE)
  55 endif()
  56
  57 # Included stuff
  58 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_SOURCE_DIR}/cmake/Modules/")
  59 include(${CMAKE_SOURCE_DIR}/cmake/Modules/misc.cmake)
  60
  61 # This is done here so that relative search paths are more reasnable
  62 find_package(Irrlicht)
  63
  64 #
  65 # Installation
  66 #
  67
  68 if(WIN32)
  69         set(SHAREDIR ".")
  70         set(BINDIR "bin")
  71         set(DOCDIR "doc")
  72         set(EXAMPLE_CONF_DIR ".")
  73         set(LOCALEDIR "locale")
  74 elseif(APPLE)
  75         set(BUNDLE_NAME ${PROJECT_NAME}.app)
  76         set(BUNDLE_PATH "${BUNDLE_NAME}")
  77         set(BINDIR ${BUNDLE_NAME}/Contents/MacOS)
  78         set(SHAREDIR ${BUNDLE_NAME}/Contents/Resources)
  79         set(DOCDIR "${SHAREDIR}/${PROJECT_NAME}")
  80         set(EXAMPLE_CONF_DIR ${DOCDIR})
  81         set(LOCALEDIR "${SHAREDIR}/locale")
  82 elseif(UNIX) # Linux, BSD etc
  83         if(RUN_IN_PLACE)
  84                 set(SHAREDIR ".")
  85                 set(BINDIR "bin")
  86                 set(DOCDIR "doc")
  87                 set(EXAMPLE_CONF_DIR ".")
  88                 set(MANDIR "unix/man")
  89                 set(XDG_APPS_DIR "unix/applications")
  90                 set(APPDATADIR "unix/appdata")
  91                 set(ICONDIR "unix/icons")
  92                 set(LOCALEDIR "locale")
  93         else()
  94                 set(SHAREDIR "${CMAKE_INSTALL_PREFIX}/share/${PROJECT_NAME}")
  95                 set(BINDIR "${CMAKE_INSTALL_PREFIX}/bin")
  96                 set(DOCDIR "${CMAKE_INSTALL_PREFIX}/share/doc/${PROJECT_NAME}")
  97                 set(MANDIR "${CMAKE_INSTALL_PREFIX}/share/man")
  98                 set(EXAMPLE_CONF_DIR ${DOCDIR})
  99                 set(XDG_APPS_DIR "${CMAKE_INSTALL_PREFIX}/share/applications")
 100                 set(APPDATADIR "${CMAKE_INSTALL_PREFIX}/share/appdata")
 101                 set(ICONDIR "${CMAKE_INSTALL_PREFIX}/share/icons")
 102                 set(LOCALEDIR "${CMAKE_INSTALL_PREFIX}/share/${PROJECT_NAME}/locale")
 103         endif()
 104 endif()
 105
 106 set(CUSTOM_SHAREDIR "" CACHE STRING "Directory to install data files into")
 107 if(NOT CUSTOM_SHAREDIR STREQUAL "")
 108         set(SHAREDIR "${CUSTOM_SHAREDIR}")
 109         message(STATUS "Using SHAREDIR=${SHAREDIR}")
 110 endif()
 111 set(CUSTOM_BINDIR "" CACHE STRING "Directory to install binaries into")
 112 if(NOT CUSTOM_BINDIR STREQUAL "")
 113         set(BINDIR "${CUSTOM_BINDIR}")
 114         message(STATUS "Using BINDIR=${BINDIR}")
 115 endif()
 116 set(CUSTOM_DOCDIR "" CACHE STRING "Directory to install documentation into")
 117 if(NOT CUSTOM_DOCDIR STREQUAL "")
 118         set(DOCDIR "${CUSTOM_DOCDIR}")
 119         message(STATUS "Using DOCDIR=${DOCDIR}")
 120 endif()
 121 set(CUSTOM_MANDIR "" CACHE STRING "Directory to install manpages into")
 122 if(NOT CUSTOM_MANDIR STREQUAL "")
 123         set(MANDIR "${CUSTOM_MANDIR}")
 124         message(STATUS "Using MANDIR=${MANDIR}")
 125 endif()
 126 set(CUSTOM_EXAMPLE_CONF_DIR "" CACHE STRING "Directory to install example config file into")
 127 if(NOT CUSTOM_EXAMPLE_CONF_DIR STREQUAL "")
 128         set(EXAMPLE_CONF_DIR "${CUSTOM_EXAMPLE_CONF_DIR}")
 129         message(STATUS "Using EXAMPLE_CONF_DIR=${EXAMPLE_CONF_DIR}")
 130 endif()
 131 set(CUSTOM_XDG_APPS_DIR "" CACHE STRING "Directory to install .desktop files into")
 132 if(NOT CUSTOM_XDG_APPS_DIR STREQUAL "")
 133         set(XDG_APPS_DIR "${CUSTOM_XDG_APPS_DIR}")
 134         message(STATUS "Using XDG_APPS_DIR=${XDG_APPS_DIR}")
 135 endif()
 136 set(CUSTOM_ICONDIR "" CACHE STRING "Directory to install icons into")
 137 if(NOT CUSTOM_ICONDIR STREQUAL "")
 138         set(ICONDIR "${CUSTOM_ICONDIR}")
 139         message(STATUS "Using ICONDIR=${ICONDIR}")
 140 endif()
 141 set(CUSTOM_LOCALEDIR "" CACHE STRING "Directory to install l10n files into")
 142 if(NOT CUSTOM_LOCALEDIR STREQUAL "")
 143         set(LOCALEDIR "${CUSTOM_LOCALEDIR}")
 144         message(STATUS "Using LOCALEDIR=${LOCALEDIR}")
 145 endif()
 146
 147 install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/builtin" DESTINATION "${SHAREDIR}")
 148 install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/client" DESTINATION "${SHAREDIR}")
 149 install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/games/minimal" DESTINATION "${SHAREDIR}/games")
 150 set(MINETEST_GAME_SOURCE "${CMAKE_CURRENT_SOURCE_DIR}/games/minetest_game")
 151 if(EXISTS ${MINETEST_GAME_SOURCE} AND IS_DIRECTORY ${MINETEST_GAME_SOURCE})
 152         install(FILES ${MINETEST_GAME_SOURCE}/game.conf DESTINATION "${SHAREDIR}/games/minetest_game/")
 153         install(FILES ${MINETEST_GAME_SOURCE}/README.txt DESTINATION "${SHAREDIR}/games/minetest_game/")
 154         install(DIRECTORY ${MINETEST_GAME_SOURCE}/mods DESTINATION "${SHAREDIR}/games/minetest_game")
 155         install(DIRECTORY ${MINETEST_GAME_SOURCE}/menu DESTINATION "${SHAREDIR}/games/minetest_game")
 156 endif()
 157 if(BUILD_CLIENT)
 158         #install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/sounds/base/pack" DESTINATION "${SHAREDIR}/sounds/base")
 159         install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/textures/base/pack" DESTINATION "${SHAREDIR}/textures/base")
 160 endif()
 161 if(RUN_IN_PLACE)
 162         install(FILES "${CMAKE_CURRENT_SOURCE_DIR}/mods/mods_here.txt" DESTINATION "${SHAREDIR}/mods")
 163         install(FILES "${CMAKE_CURRENT_SOURCE_DIR}/textures/texture_packs_here.txt" DESTINATION "${SHAREDIR}/textures")
 164 endif()
 165
 166 install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/fonts" DESTINATION "${SHAREDIR}")
 167
 168 install(FILES "README.txt" DESTINATION "${DOCDIR}")
 169 install(FILES "doc/lua_api.txt" DESTINATION "${DOCDIR}")
 170 install(FILES "doc/menu_lua_api.txt" DESTINATION "${DOCDIR}")
 171 install(FILES "doc/mapformat.txt" DESTINATION "${DOCDIR}")
 172 install(FILES "minetest.conf.example" DESTINATION "${EXAMPLE_CONF_DIR}")
 173
 174 if(UNIX AND NOT APPLE)
 175         install(FILES "doc/minetest.6" "doc/minetestserver.6" DESTINATION "${MANDIR}/man6")
 176         install(FILES "misc/minetest.desktop" DESTINATION "${XDG_APPS_DIR}")
 177         install(FILES "misc/minetest.appdata.xml" DESTINATION "${APPDATADIR}")
 178         install(FILES "misc/minetest-icon.svg" DESTINATION "${ICONDIR}/hicolor/scalable/apps")
 179 endif()
 180
 181 if(APPLE)
 182         install(FILES "misc/minetest-icon.icns" DESTINATION "${SHAREDIR}")
 183         install(FILES "misc/Info.plist" DESTINATION "${BUNDLE_PATH}/Contents")
 184 endif()
 185
 186 #
 187 # Subdirectories
 188 # Be sure to add all relevant definitions above this
 189 #
 190
 191 add_subdirectory(src)
 192
 193 # CPack
 194
 195 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "An InfiniMiner/Minecraft inspired game")
 196 set(CPACK_PACKAGE_VERSION_MAJOR ${VERSION_MAJOR})
 197 set(CPACK_PACKAGE_VERSION_MINOR ${VERSION_MINOR})
 198 set(CPACK_PACKAGE_VERSION_PATCH ${VERSION_PATCH})
 199 set(CPACK_PACKAGE_VENDOR "celeron55")
 200 set(CPACK_PACKAGE_CONTACT "Perttu Ahola <celeron55@gmail.com>")
 201
 202 if(WIN32)
 203         if(CMAKE_SIZEOF_VOID_P EQUAL 8)
 204                 set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-win64")
 205         else(CMAKE_SIZEOF_VOID_P EQUAL 8)
 206                 set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-win32")
 207         endif(CMAKE_SIZEOF_VOID_P EQUAL 8)
 208
 209         set(CPACK_GENERATOR ZIP)
 210 elseif(APPLE)
 211         set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
 212         set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-osx")
 213         set(CPACK_GENERATOR ZIP)
 214 else()
 215         set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-linux")
 216         set(CPACK_GENERATOR TGZ)
 217         set(CPACK_SOURCE_GENERATOR TGZ)
 218 endif()
 219
 220 include(CPack)
 221
 222 # Add a target to generate API documentation with Doxygen
 223 find_package(Doxygen)
 224 if(DOXYGEN_FOUND)
 225         configure_file(${CMAKE_CURRENT_SOURCE_DIR}/doc/Doxyfile.in ${CMAKE_CURRENT_BINARY_DIR}/doc/Doxyfile @ONLY)
 226         add_custom_target(doc
 227                 ${DOXYGEN_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/doc/Doxyfile
 228                 WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/doc
 229                 COMMENT "Generating API documentation with Doxygen" VERBATIM
 230         )
 231 endif(DOXYGEN_FOUND)
 232