CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 if(${CMAKE_VERSION} STREQUAL "2.8.2")
   4         # Bug http://vtk.org/Bug/view.php?id=11020
   5         message(WARNING "CMake/CPack version 2.8.2 will not create working .deb packages!")
   6 endif()
   7
   8 # This can be read from ${PROJECT_NAME} after project() is called
   9 project(minetest)
  10 set(PROJECT_NAME_CAPITALIZED "Minetest")
  11
  12 # Works only for cmake 3.1 and greater
  13 set(CMAKE_CXX_STANDARD 11)
  14 set(GCC_MINIMUM_VERSION "4.8")
  15 set(CLANG_MINIMUM_VERSION "3.4")
  16
  17 # Also remember to set PROTOCOL_VERSION in network/networkprotocol.h when releasing
  18 set(VERSION_MAJOR 5)
  19 set(VERSION_MINOR 2)
  20 set(VERSION_PATCH 0)
  21 set(VERSION_EXTRA "" CACHE STRING "Stuff to append to version string")
  22
  23 # Change to false for releases
  24 set(DEVELOPMENT_BUILD TRUE)
  25
  26 set(VERSION_STRING "${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH}")
  27 if(VERSION_EXTRA)
  28         set(VERSION_STRING ${VERSION_STRING}-${VERSION_EXTRA})
  29 elseif(DEVELOPMENT_BUILD)
  30         set(VERSION_STRING "${VERSION_STRING}-dev")
  31 endif()
  32
  33 if (CMAKE_BUILD_TYPE STREQUAL Debug)
  34         # Append "-debug" to version string
  35         set(VERSION_STRING "${VERSION_STRING}-debug")
  36 endif()
  37
  38 message(STATUS "*** Will build version ${VERSION_STRING} ***")
  39
  40
  41 # Configuration options
  42 set(DEFAULT_RUN_IN_PLACE FALSE)
  43 if(WIN32)
  44         set(DEFAULT_RUN_IN_PLACE TRUE)
  45 endif()
  46 set(RUN_IN_PLACE ${DEFAULT_RUN_IN_PLACE} CACHE BOOL
  47         "Run directly in source directory structure")
  48
  49
  50 set(BUILD_CLIENT TRUE CACHE BOOL "Build client")
  51 set(BUILD_SERVER FALSE CACHE BOOL "Build server")
  52
  53
  54 set(WARN_ALL TRUE CACHE BOOL "Enable -Wall for Release build")
  55
  56 if(NOT CMAKE_BUILD_TYPE)
  57         # Default to release
  58         set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type: Debug or Release" FORCE)
  59 endif()
  60
  61 # Included stuff
  62 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_SOURCE_DIR}/cmake/Modules/")
  63
  64
  65 # This is done here so that relative search paths are more reasonable
  66 find_package(Irrlicht)
  67
  68
  69 # Installation
  70
  71 if(WIN32)
  72         set(SHAREDIR ".")
  73         set(BINDIR "bin")
  74         set(DOCDIR "doc")
  75         set(EXAMPLE_CONF_DIR ".")
  76         set(LOCALEDIR "locale")
  77 elseif(APPLE)
  78         set(BUNDLE_NAME ${PROJECT_NAME}.app)
  79         set(BUNDLE_PATH "${BUNDLE_NAME}")
  80         set(BINDIR ${BUNDLE_NAME}/Contents/MacOS)
  81         set(SHAREDIR ${BUNDLE_NAME}/Contents/Resources)
  82         set(DOCDIR "${SHAREDIR}/${PROJECT_NAME}")
  83         set(EXAMPLE_CONF_DIR ${DOCDIR})
  84         set(LOCALEDIR "${SHAREDIR}/locale")
  85 elseif(UNIX) # Linux, BSD etc
  86         if(RUN_IN_PLACE)
  87                 set(SHAREDIR ".")
  88                 set(BINDIR "bin")
  89                 set(DOCDIR "doc")
  90                 set(EXAMPLE_CONF_DIR ".")
  91                 set(MANDIR "unix/man")
  92                 set(XDG_APPS_DIR "unix/applications")
  93                 set(APPDATADIR "unix/metainfo")
  94                 set(ICONDIR "unix/icons")
  95                 set(LOCALEDIR "locale")
  96         else()
  97                 set(SHAREDIR "${CMAKE_INSTALL_PREFIX}/share/${PROJECT_NAME}")
  98                 set(BINDIR "${CMAKE_INSTALL_PREFIX}/bin")
  99                 set(DOCDIR "${CMAKE_INSTALL_PREFIX}/share/doc/${PROJECT_NAME}")
 100                 set(MANDIR "${CMAKE_INSTALL_PREFIX}/share/man")
 101                 set(EXAMPLE_CONF_DIR ${DOCDIR})
 102                 set(XDG_APPS_DIR "${CMAKE_INSTALL_PREFIX}/share/applications")
 103                 set(APPDATADIR "${CMAKE_INSTALL_PREFIX}/share/metainfo")
 104                 set(ICONDIR "${CMAKE_INSTALL_PREFIX}/share/icons")
 105                 set(LOCALEDIR "${CMAKE_INSTALL_PREFIX}/share/${PROJECT_NAME}/locale")
 106         endif()
 107 endif()
 108
 109 set(CUSTOM_SHAREDIR "" CACHE STRING "Directory to install data files into")
 110 if(NOT CUSTOM_SHAREDIR STREQUAL "")
 111         set(SHAREDIR "${CUSTOM_SHAREDIR}")
 112         message(STATUS "Using SHAREDIR=${SHAREDIR}")
 113 endif()
 114
 115 set(CUSTOM_BINDIR "" CACHE STRING "Directory to install binaries into")
 116 if(NOT CUSTOM_BINDIR STREQUAL "")
 117         set(BINDIR "${CUSTOM_BINDIR}")
 118         message(STATUS "Using BINDIR=${BINDIR}")
 119 endif()
 120
 121 set(CUSTOM_DOCDIR "" CACHE STRING "Directory to install documentation into")
 122 if(NOT CUSTOM_DOCDIR STREQUAL "")
 123         set(DOCDIR "${CUSTOM_DOCDIR}")
 124         if(NOT RUN_IN_PLACE)
 125                 set(EXAMPLE_CONF_DIR ${DOCDIR})
 126         endif()
 127         message(STATUS "Using DOCDIR=${DOCDIR}")
 128 endif()
 129
 130 set(CUSTOM_MANDIR "" CACHE STRING "Directory to install manpages into")
 131 if(NOT CUSTOM_MANDIR STREQUAL "")
 132         set(MANDIR "${CUSTOM_MANDIR}")
 133         message(STATUS "Using MANDIR=${MANDIR}")
 134 endif()
 135
 136 set(CUSTOM_EXAMPLE_CONF_DIR "" CACHE STRING "Directory to install example config file into")
 137 if(NOT CUSTOM_EXAMPLE_CONF_DIR STREQUAL "")
 138         set(EXAMPLE_CONF_DIR "${CUSTOM_EXAMPLE_CONF_DIR}")
 139         message(STATUS "Using EXAMPLE_CONF_DIR=${EXAMPLE_CONF_DIR}")
 140 endif()
 141
 142 set(CUSTOM_XDG_APPS_DIR "" CACHE STRING "Directory to install .desktop files into")
 143 if(NOT CUSTOM_XDG_APPS_DIR STREQUAL "")
 144         set(XDG_APPS_DIR "${CUSTOM_XDG_APPS_DIR}")
 145         message(STATUS "Using XDG_APPS_DIR=${XDG_APPS_DIR}")
 146 endif()
 147
 148 set(CUSTOM_ICONDIR "" CACHE STRING "Directory to install icons into")
 149 if(NOT CUSTOM_ICONDIR STREQUAL "")
 150         set(ICONDIR "${CUSTOM_ICONDIR}")
 151         message(STATUS "Using ICONDIR=${ICONDIR}")
 152 endif()
 153
 154 set(CUSTOM_LOCALEDIR "" CACHE STRING "Directory to install l10n files into")
 155 if(NOT CUSTOM_LOCALEDIR STREQUAL "")
 156         set(LOCALEDIR "${CUSTOM_LOCALEDIR}")
 157         message(STATUS "Using LOCALEDIR=${LOCALEDIR}")
 158 endif()
 159
 160
 161 install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/builtin" DESTINATION "${SHAREDIR}")
 162 if(RUN_IN_PLACE)
 163         install(FILES "${CMAKE_CURRENT_SOURCE_DIR}/mods/mods_here.txt" DESTINATION "${SHAREDIR}/mods")
 164         install(FILES "${CMAKE_CURRENT_SOURCE_DIR}/textures/texture_packs_here.txt" DESTINATION "${SHAREDIR}/textures")
 165 endif()
 166
 167 install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/games/minetest_game" DESTINATION "${SHAREDIR}/games/"
 168         COMPONENT "SUBGAME_MINETEST_GAME" OPTIONAL PATTERN ".git*" EXCLUDE )
 169 install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/games/minimal" DESTINATION "${SHAREDIR}/games/"
 170         COMPONENT "SUBGAME_MINIMAL" OPTIONAL PATTERN ".git*" EXCLUDE )
 171
 172 if(BUILD_CLIENT)
 173         install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/client/shaders" DESTINATION "${SHAREDIR}/client")
 174         install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/textures/base/pack" DESTINATION "${SHAREDIR}/textures/base")
 175         install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/fonts" DESTINATION "${SHAREDIR}")
 176         if(RUN_IN_PLACE)
 177                 install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/clientmods" DESTINATION "${SHAREDIR}")
 178                 install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/client/serverlist" DESTINATION "${SHAREDIR}/client")
 179         endif()
 180 endif()
 181
 182 install(FILES "README.md" DESTINATION "${DOCDIR}" COMPONENT "Docs")
 183 install(FILES "doc/lua_api.txt" DESTINATION "${DOCDIR}" COMPONENT "Docs")
 184 install(FILES "doc/menu_lua_api.txt" DESTINATION "${DOCDIR}" COMPONENT "Docs")
 185 install(FILES "doc/texture_packs.txt" DESTINATION "${DOCDIR}" COMPONENT "Docs")
 186 install(FILES "doc/world_format.txt" DESTINATION "${DOCDIR}" COMPONENT "Docs")
 187 install(FILES "minetest.conf.example" DESTINATION "${EXAMPLE_CONF_DIR}")
 188
 189 if(UNIX AND NOT APPLE)
 190         install(FILES "doc/minetest.6" "doc/minetestserver.6" DESTINATION "${MANDIR}/man6")
 191         install(FILES "misc/net.minetest.minetest.desktop" DESTINATION "${XDG_APPS_DIR}")
 192         install(FILES "misc/net.minetest.minetest.appdata.xml" DESTINATION "${APPDATADIR}")
 193         install(FILES "misc/minetest.svg" DESTINATION "${ICONDIR}/hicolor/scalable/apps")
 194         install(FILES "misc/minetest-xorg-icon-128.png"
 195                 DESTINATION "${ICONDIR}/hicolor/128x128/apps"
 196                 RENAME "minetest.png")
 197 endif()
 198
 199 if(APPLE)
 200         install(FILES "misc/minetest-icon.icns" DESTINATION "${SHAREDIR}")
 201         install(FILES "misc/Info.plist" DESTINATION "${BUNDLE_PATH}/Contents")
 202 endif()
 203
 204 # Library pack
 205 find_package(GMP REQUIRED)
 206 find_package(Json REQUIRED)
 207 find_package(Lua REQUIRED)
 208
 209 # JsonCPP doesn't compile well on GCC 4.8
 210 if(NOT ENABLE_SYSTEM_JSONCPP)
 211         set(GCC_MINIMUM_VERSION "4.9")
 212 endif()
 213
 214 if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
 215         if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS "${GCC_MINIMUM_VERSION}")
 216                 message(FATAL_ERROR "Insufficient gcc version, found ${CMAKE_CXX_COMPILER_VERSION}. "
 217                         "Version ${GCC_MINIMUM_VERSION} or higher is required.")
 218         endif()
 219 elseif(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 220         if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "${CLANG_MINIMUM_VERSION}")
 221                 message(FATAL_ERROR "Insufficient clang version, found ${CMAKE_CXX_COMPILER_VERSION}. "
 222                         "Version ${CLANG_MINIMUM_VERSION} or higher is required.")
 223         endif()
 224 endif()
 225
 226 # Subdirectories
 227 # Be sure to add all relevant definitions above this
 228
 229 add_subdirectory(src)
 230
 231
 232 # CPack
 233
 234 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "A free open-source voxel game engine with easy modding and game creation.")
 235 set(CPACK_PACKAGE_VERSION_MAJOR ${VERSION_MAJOR})
 236 set(CPACK_PACKAGE_VERSION_MINOR ${VERSION_MINOR})
 237 set(CPACK_PACKAGE_VERSION_PATCH ${VERSION_PATCH})
 238 set(CPACK_PACKAGE_VENDOR "celeron55")
 239 set(CPACK_PACKAGE_CONTACT "Perttu Ahola <celeron55@gmail.com>")
 240
 241 include(CPackComponent)
 242
 243 cpack_add_component(Docs
 244         DISPLAY_NAME "Documentation"
 245         DESCRIPTION "Documentation about Minetest and Minetest modding"
 246 )
 247
 248 cpack_add_component(SUBGAME_MINETEST_GAME
 249         DISPLAY_NAME "Minetest Game"
 250         DESCRIPTION "The official subgame for the Minetest engine, that can easily extended by mods."
 251         GROUP "Subgames"
 252 )
 253
 254 cpack_add_component(SUBGAME_MINIMAL
 255         DISPLAY_NAME "Minimal development test"
 256         DESCRIPTION "A minimal subgame helping to develop the engine."
 257         DISABLED #DISABLED does not mean it is disabled, and is just not selected by default.
 258         GROUP "Subgames"
 259 )
 260
 261 cpack_add_component_group(Subgames
 262         DESCRIPTION "Games for the Minetest engine."
 263 )
 264
 265 if(WIN32)
 266         # Include all dynamically linked runtime libaries such as MSVCRxxx.dll
 267         include(InstallRequiredSystemLibraries)
 268
 269         if(RUN_IN_PLACE)
 270                 if(CMAKE_SIZEOF_VOID_P EQUAL 8)
 271                         set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-win64")
 272                 else()
 273                         set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-win32")
 274                 endif()
 275
 276                 set(CPACK_GENERATOR ZIP)
 277
 278         else()
 279                 set(CPACK_GENERATOR WIX ZIP)
 280                 set(CPACK_PACKAGE_NAME "${PROJECT_NAME_CAPITALIZED}")
 281                 set(CPACK_PACKAGE_INSTALL_DIRECTORY "${PROJECT_NAME_CAPITALIZED}")
 282                 set(CPACK_PACKAGE_EXECUTABLES ${PROJECT_NAME} "${PROJECT_NAME_CAPITALIZED}")
 283                 set(CPACK_CREATE_DESKTOP_LINKS ${PROJECT_NAME})
 284
 285                 set(CPACK_WIX_PRODUCT_ICON "${CMAKE_CURRENT_SOURCE_DIR}/misc/minetest-icon.ico")
 286                 # Supported languages can be found at
 287                 # http://wixtoolset.org/documentation/manual/v3/wixui/wixui_localization.html
 288                 #set(CPACK_WIX_CULTURES "ar-SA,bg-BG,ca-ES,hr-HR,cs-CZ,da-DK,nl-NL,en-US,et-EE,fi-FI,fr-FR,de-DE")
 289                 set(CPACK_WIX_UI_BANNER "${CMAKE_CURRENT_SOURCE_DIR}/misc/CPACK_WIX_UI_BANNER.BMP")
 290                 set(CPACK_WIX_UI_DIALOG "${CMAKE_CURRENT_SOURCE_DIR}/misc/CPACK_WIX_UI_DIALOG.BMP")
 291
 292                 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/doc/lgpl-2.1.txt")
 293
 294                 # The correct way would be to include both x32 and x64 into one installer
 295                 # and install the appropriate one.
 296                 # CMake does not support that, so there are two separate GUID's
 297                 if(CMAKE_SIZEOF_VOID_P EQUAL 8)
 298                         set(CPACK_WIX_UPGRADE_GUID "745A0FB3-5552-44CA-A587-A91C397CCC56")
 299                 else()
 300                         set(CPACK_WIX_UPGRADE_GUID "814A2E2D-2779-4BBD-9ACD-FC3BD51FBBA2")
 301                 endif()
 302         endif()
 303 elseif(APPLE)
 304         set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
 305         set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-osx")
 306         set(CPACK_GENERATOR ZIP)
 307 else()
 308         set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-linux")
 309         set(CPACK_GENERATOR TGZ)
 310         set(CPACK_SOURCE_GENERATOR TGZ)
 311 endif()
 312
 313 include(CPack)
 314
 315
 316 # Add a target to generate API documentation with Doxygen
 317 find_package(Doxygen)
 318 if(DOXYGEN_FOUND)
 319         configure_file(${CMAKE_CURRENT_SOURCE_DIR}/doc/Doxyfile.in
 320                         ${CMAKE_CURRENT_BINARY_DIR}/doc/Doxyfile @ONLY)
 321         add_custom_target(doc
 322                 ${DOXYGEN_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/doc/Doxyfile
 323                 WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/doc
 324                 COMMENT "Generating API documentation with Doxygen" VERBATIM
 325         )
 326 endif()
 327