CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2 if(${CMAKE_VERSION} STREQUAL "2.8.2")
   3   # bug http://vtk.org/Bug/view.php?id=11020
   4   message( WARNING "CMake/CPack version 2.8.2 will not create working .deb packages!")
   5 endif(${CMAKE_VERSION} STREQUAL "2.8.2")
   6
   7 # This can be read from ${PROJECT_NAME} after project() is called
   8 project(minetest)
   9
  10 # Also remember to set PROTOCOL_VERSION in clientserver.h when releasing
  11 set(VERSION_MAJOR 0)
  12 set(VERSION_MINOR 4)
  13 set(VERSION_PATCH dev-20120326)
  14 set(VERSION_STRING "${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH}")
  15
  16 MESSAGE(STATUS "*** Will build version ${VERSION_STRING} ***")
  17
  18 # Configuration options
  19
  20 if(WIN32)
  21         set(RUN_IN_PLACE 1 CACHE BOOL "Run directly in source directory structure")
  22 else()
  23         set(RUN_IN_PLACE 0 CACHE BOOL "Run directly in source directory structure")
  24 endif()
  25
  26 set(BUILD_CLIENT 1 CACHE BOOL "Build client")
  27 if(WIN32)
  28         set(BUILD_SERVER 0 CACHE BOOL "Build server")
  29 else()
  30         set(BUILD_SERVER 1 CACHE BOOL "Build server")
  31 endif()
  32
  33 set(WARN_ALL 1 CACHE BOOL "Enable -Wall for Release build")
  34
  35 if(NOT CMAKE_BUILD_TYPE)
  36         # Default to release
  37         set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type: Debug or Release" FORCE)
  38 endif()
  39
  40 # Included stuff
  41 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_SOURCE_DIR}/cmake/Modules/")
  42 include(${CMAKE_SOURCE_DIR}/cmake/Modules/misc.cmake)
  43
  44 # This is done here so that relative search paths are more reasnable
  45 find_package(Irrlicht)
  46
  47 #
  48 # Installation
  49 #
  50
  51 if(WIN32)
  52         set(SHAREDIR ".")
  53         set(BINDIR "bin")
  54         set(DOCDIR "doc")
  55         set(EXAMPLE_CONF_DIR ".")
  56         set(LOCALEDIR "locale")
  57 elseif(APPLE)
  58         # Random placeholders; this isn't usually used and may not work
  59         # See https://github.com/toabi/minetest-mac/
  60         set(SHAREDIR "share/${PROJECT_NAME}")
  61         set(BINDIR "bin")
  62         set(DOCDIR "share/doc/${PROJECT_NAME}")
  63         set(EXAMPLE_CONF_DIR ${DOCDIR})
  64         set(LOCALEDIR "locale")
  65 elseif(UNIX) # Linux, BSD etc
  66         if(RUN_IN_PLACE)
  67                 set(SHAREDIR ".")
  68                 set(BINDIR "bin")
  69                 set(DOCDIR "doc")
  70                 set(EXAMPLE_CONF_DIR ".")
  71                 set(MANDIR "unix/man")
  72                 set(XDG_APPS_DIR "unix/applications")
  73                 set(ICONDIR "unix/icons")
  74                 set(LOCALEDIR "locale")
  75         else()
  76                 set(SHAREDIR "share/${PROJECT_NAME}")
  77                 set(BINDIR "bin")
  78                 set(DOCDIR "share/doc/${PROJECT_NAME}")
  79                 set(MANDIR "share/man")
  80                 set(EXAMPLE_CONF_DIR ${DOCDIR})
  81                 set(XDG_APPS_DIR "share/applications")
  82                 set(ICONDIR "share/icons")
  83                 set(LOCALEDIR "share/locale")
  84         endif()
  85 endif()
  86
  87 install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/builtin" DESTINATION "${SHAREDIR}")
  88 install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/games/minimal" DESTINATION "${SHAREDIR}/games")
  89 set(MINETEST_GAME_SOURCE "${CMAKE_CURRENT_SOURCE_DIR}/games/minetest_game")
  90 if(EXISTS ${MINETEST_GAME_SOURCE} AND IS_DIRECTORY ${MINETEST_GAME_SOURCE})
  91         install(FILES ${MINETEST_GAME_SOURCE}/game.conf DESTINATION "${SHAREDIR}/games/minetest_game/")
  92         install(FILES ${MINETEST_GAME_SOURCE}/README.txt DESTINATION "${SHAREDIR}/games/minetest_game/")
  93         install(DIRECTORY ${MINETEST_GAME_SOURCE}/mods DESTINATION "${SHAREDIR}/games/minetest_game/")
  94 endif()
  95 if(BUILD_CLIENT)
  96         #install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/sounds/base/pack" DESTINATION "${SHAREDIR}/sounds/base")
  97         install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/textures/base/pack" DESTINATION "${SHAREDIR}/textures/base")
  98 endif()
  99 if(RUN_IN_PLACE)
 100         install(FILES "${CMAKE_CURRENT_SOURCE_DIR}/mods/minetest/mods_here.txt" DESTINATION "${SHAREDIR}/mods/minetest")
 101 endif()
 102
 103 install(FILES "README.txt" DESTINATION "${DOCDIR}")
 104 install(FILES "doc/lua_api.txt" DESTINATION "${DOCDIR}")
 105 install(FILES "doc/mapformat.txt" DESTINATION "${DOCDIR}")
 106 install(FILES "minetest.conf.example" DESTINATION "${EXAMPLE_CONF_DIR}")
 107
 108 if(UNIX)
 109         install(FILES "doc/minetest.6" "doc/minetestserver.6" DESTINATION "${MANDIR}/man6")
 110         install(FILES "misc/minetest.desktop" DESTINATION "${XDG_APPS_DIR}")
 111         install(FILES "misc/minetest-icon.svg" DESTINATION "${ICONDIR}/hicolor/scalable/apps")
 112 endif()
 113
 114 #
 115 # Subdirectories
 116 # Be sure to add all relevant definitions above this
 117 #
 118
 119 add_subdirectory(src)
 120
 121 # CPack
 122
 123 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "An InfiniMiner/Minecraft inspired game")
 124 set(CPACK_PACKAGE_VERSION_MAJOR ${VERSION_MAJOR})
 125 set(CPACK_PACKAGE_VERSION_MINOR ${VERSION_MINOR})
 126 set(CPACK_PACKAGE_VERSION_PATCH ${VERSION_PATCH})
 127 set(CPACK_PACKAGE_VENDOR "celeron55")
 128 set(CPACK_PACKAGE_CONTACT "Perttu Ahola <celeron55@gmail.com>")
 129
 130 if(WIN32)
 131         # For some reason these aren't copied otherwise
 132         # NOTE: For some reason now it seems to work without these
 133         #if(BUILD_CLIENT)
 134         #       install(FILES bin/minetest.exe DESTINATION bin)
 135         #endif()
 136         #if(BUILD_SERVER)
 137         #       install(FILES bin/minetestserver.exe DESTINATION bin)
 138         #endif()
 139
 140         set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-win32")
 141
 142         set(CPACK_GENERATOR ZIP)
 143
 144         # This might be needed for some installer
 145         #set(CPACK_PACKAGE_EXECUTABLES bin/minetest.exe "Minetest" bin/minetestserver.exe "Minetest Server")
 146 elseif(APPLE)
 147         # TODO
 148         # see http://cmake.org/Wiki/CMake:CPackPackageGenerators#Bundle_.28OSX_only.29
 149         #
 150         set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-osx")
 151         set(CPACK_PACKAGE_ICON "")
 152         set(CPACK_BUNDLE_NAME ${PROJECT_NAME})
 153         set(CPACK_BUNDLE_ICON "")
 154         set(CPACK_BUNDLE_PLIST "")
 155         set(CPACK_BUNDLE_STARTUP_COMMAND "Contents/MacOS/${PROJECT_NAME}")
 156         set(CPACK_GENERATOR "Bundle")
 157 else()
 158         set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-linux")
 159         set(CPACK_GENERATOR TGZ)
 160         set(CPACK_SOURCE_GENERATOR TGZ)
 161 endif()
 162
 163 include(CPack)
 164