CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2 if(${CMAKE_VERSION} STREQUAL "2.8.2")
   3   # bug http://vtk.org/Bug/view.php?id=11020
   4   message( WARNING "CMake/CPack version 2.8.2 will not create working .deb packages!")
   5 endif(${CMAKE_VERSION} STREQUAL "2.8.2")
   6
   7 # This can be read from ${PROJECT_NAME} after project() is called
   8 project(minetest)
   9
  10 set(VERSION_MAJOR 0)
  11 set(VERSION_MINOR 0)
  12 set(VERSION_PATCH 1)
  13 set(VERSION_STRING "${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH}")
  14
  15 # Configuration options
  16
  17 set(RUN_IN_PLACE 0 CACHE BOOL "Run directly in source directory structure")
  18
  19 set(BUILD_CLIENT 1 CACHE BOOL "Build client")
  20 set(BUILD_SERVER 1 CACHE BOOL "Build server")
  21
  22 set(WARN_ALL 1 CACHE BOOL "Enable -Wall for Release build")
  23
  24 if(NOT CMAKE_BUILD_TYPE)
  25         # Default to release
  26         set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type: Debug or Release" FORCE)
  27 endif()
  28
  29 # Included stuff
  30 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_SOURCE_DIR}/cmake/Modules/")
  31 include(${CMAKE_SOURCE_DIR}/cmake/Modules/misc.cmake)
  32
  33 # This is done here so that relative search paths are more reasnable
  34 find_package(Irrlicht)
  35
  36 #
  37 # Installation
  38 #
  39
  40 if(WIN32)
  41         set(DATADIR "data")
  42         set(BINDIR "bin")
  43         set(DOCDIR "doc")
  44 elseif(APPLE)
  45         set(DATADIR "share/minetest")
  46         set(BINDIR "bin")
  47         set(DOCDIR "share/doc/minetest")
  48 elseif(UNIX)
  49         set(DATADIR "share/minetest")
  50         set(BINDIR "bin")
  51         set(DOCDIR "share/doc/minetest")
  52 endif()
  53
  54 install(FILES "doc/README.txt" DESTINATION "${DOCDIR}")
  55 install(FILES "minetest.conf.example" DESTINATION "${DOCDIR}")
  56
  57 #
  58 # Subdirectories
  59 # Be sure to add all relevant definitions above this
  60 #
  61
  62 add_subdirectory(src)
  63
  64 # CPack
  65
  66 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "An InfiniMiner/Minecraft inspired game")
  67 set(CPACK_PACKAGE_VERSION_MAJOR ${VERSION_MAJOR})
  68 set(CPACK_PACKAGE_VERSION_MINOR ${VERSION_MINOR})
  69 set(CPACK_PACKAGE_VERSION_PATCH ${VERSION_PATCH})
  70 set(CPACK_PACKAGE_VENDOR "celeron55")
  71
  72 if(WIN32)
  73         # For some reason these aren't copied otherwise
  74         if(BUILD_CLIENT)
  75                 install(FILES bin/minetest.exe DESTINATION bin)
  76         endif()
  77         if(BUILD_SERVER)
  78                 install(FILES bin/minetestserver.exe DESTINATION bin)
  79         endif()
  80
  81         set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-win32")
  82
  83         set(CPACK_GENERATOR ZIP)
  84
  85         # This might be needed for some installer
  86         #set(CPACK_PACKAGE_EXECUTABLES bin/minetest.exe "Minetest" bin/minetestserver.exe "Minetest Server")
  87 elseif(APPLE)
  88         # TODO
  89         # see http://cmake.org/Wiki/CMake:CPackPackageGenerators#Bundle_.28OSX_only.29
  90         # this too http://0xfe.blogspot.com/2006/03/how-os-x-executes-applications.html
  91         #
  92         set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-osx")
  93         set(CPACK_PACKAGE_ICON "")
  94         set(CPACK_BUNDLE_NAME ${PROJECT_NAME})
  95         set(CPACK_BUNDLE_ICON "")
  96         set(CPACK_BUNDLE_PLIST "")
  97         set(CPACK_BUNDLE_STARTUP_COMMAND "Contents/MacOS/minetest")
  98         set(CPACK_GENERATOR BUNDLE)
  99 else()
 100         set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-linux")
 101         set(CPACK_GENERATOR TGZ)
 102         set(CPACK_SOURCE_GENERATOR TGZ)
 103 endif()
 104
 105 include(CPack)
 106