CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 if(${CMAKE_VERSION} STREQUAL "2.8.2")
   4         # Bug http://vtk.org/Bug/view.php?id=11020
   5         message(WARNING "CMake/CPack version 2.8.2 will not create working .deb packages!")
   6 endif()
   7
   8 # This can be read from ${PROJECT_NAME} after project() is called
   9 project(minetest)
  10 set(PROJECT_NAME_CAPITALIZED "Minetest")
  11
  12 # Works only for cmake 3.1 and greater
  13 set(CMAKE_CXX_STANDARD 11)
  14
  15 # Also remember to set PROTOCOL_VERSION in network/networkprotocol.h when releasing
  16 set(VERSION_MAJOR 0)
  17 set(VERSION_MINOR 5)
  18 set(VERSION_PATCH 0)
  19 set(VERSION_EXTRA "" CACHE STRING "Stuff to append to version string")
  20
  21 # Change to false for releases
  22 set(DEVELOPMENT_BUILD TRUE)
  23
  24 set(VERSION_STRING "${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH}")
  25 if(VERSION_EXTRA)
  26         set(VERSION_STRING ${VERSION_STRING}-${VERSION_EXTRA})
  27 elseif(DEVELOPMENT_BUILD)
  28         set(VERSION_STRING "${VERSION_STRING}-dev")
  29 endif()
  30
  31 if (CMAKE_BUILD_TYPE STREQUAL Debug)
  32         # Append "-debug" to version string
  33         set(VERSION_STRING "${VERSION_STRING}-debug")
  34 endif()
  35
  36 message(STATUS "*** Will build version ${VERSION_STRING} ***")
  37
  38
  39 # Configuration options
  40 set(DEFAULT_RUN_IN_PLACE FALSE)
  41 if(WIN32)
  42         set(DEFAULT_RUN_IN_PLACE TRUE)
  43 endif()
  44 set(RUN_IN_PLACE ${DEFAULT_RUN_IN_PLACE} CACHE BOOL
  45         "Run directly in source directory structure")
  46
  47
  48 set(BUILD_CLIENT TRUE CACHE BOOL "Build client")
  49 set(BUILD_SERVER FALSE CACHE BOOL "Build server")
  50
  51
  52 set(WARN_ALL TRUE CACHE BOOL "Enable -Wall for Release build")
  53
  54 if(NOT CMAKE_BUILD_TYPE)
  55         # Default to release
  56         set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type: Debug or Release" FORCE)
  57 endif()
  58
  59 # Included stuff
  60 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_SOURCE_DIR}/cmake/Modules/")
  61
  62
  63 # This is done here so that relative search paths are more reasonable
  64 find_package(Irrlicht)
  65
  66
  67 # Installation
  68
  69 if(WIN32)
  70         set(SHAREDIR ".")
  71         set(BINDIR "bin")
  72         set(DOCDIR "doc")
  73         set(EXAMPLE_CONF_DIR ".")
  74         set(LOCALEDIR "locale")
  75 elseif(APPLE)
  76         set(BUNDLE_NAME ${PROJECT_NAME}.app)
  77         set(BUNDLE_PATH "${BUNDLE_NAME}")
  78         set(BINDIR ${BUNDLE_NAME}/Contents/MacOS)
  79         set(SHAREDIR ${BUNDLE_NAME}/Contents/Resources)
  80         set(DOCDIR "${SHAREDIR}/${PROJECT_NAME}")
  81         set(EXAMPLE_CONF_DIR ${DOCDIR})
  82         set(LOCALEDIR "${SHAREDIR}/locale")
  83 elseif(UNIX) # Linux, BSD etc
  84         if(RUN_IN_PLACE)
  85                 set(SHAREDIR ".")
  86                 set(BINDIR "bin")
  87                 set(DOCDIR "doc")
  88                 set(EXAMPLE_CONF_DIR ".")
  89                 set(MANDIR "unix/man")
  90                 set(XDG_APPS_DIR "unix/applications")
  91                 set(APPDATADIR "unix/metainfo")
  92                 set(ICONDIR "unix/icons")
  93                 set(LOCALEDIR "locale")
  94         else()
  95                 set(SHAREDIR "${CMAKE_INSTALL_PREFIX}/share/${PROJECT_NAME}")
  96                 set(BINDIR "${CMAKE_INSTALL_PREFIX}/bin")
  97                 set(DOCDIR "${CMAKE_INSTALL_PREFIX}/share/doc/${PROJECT_NAME}")
  98                 set(MANDIR "${CMAKE_INSTALL_PREFIX}/share/man")
  99                 set(EXAMPLE_CONF_DIR ${DOCDIR})
 100                 set(XDG_APPS_DIR "${CMAKE_INSTALL_PREFIX}/share/applications")
 101                 set(APPDATADIR "${CMAKE_INSTALL_PREFIX}/share/metainfo")
 102                 set(ICONDIR "${CMAKE_INSTALL_PREFIX}/share/icons")
 103                 set(LOCALEDIR "${CMAKE_INSTALL_PREFIX}/share/${PROJECT_NAME}/locale")
 104         endif()
 105 endif()
 106
 107 set(CUSTOM_SHAREDIR "" CACHE STRING "Directory to install data files into")
 108 if(NOT CUSTOM_SHAREDIR STREQUAL "")
 109         set(SHAREDIR "${CUSTOM_SHAREDIR}")
 110         message(STATUS "Using SHAREDIR=${SHAREDIR}")
 111 endif()
 112
 113 set(CUSTOM_BINDIR "" CACHE STRING "Directory to install binaries into")
 114 if(NOT CUSTOM_BINDIR STREQUAL "")
 115         set(BINDIR "${CUSTOM_BINDIR}")
 116         message(STATUS "Using BINDIR=${BINDIR}")
 117 endif()
 118
 119 set(CUSTOM_DOCDIR "" CACHE STRING "Directory to install documentation into")
 120 if(NOT CUSTOM_DOCDIR STREQUAL "")
 121         set(DOCDIR "${CUSTOM_DOCDIR}")
 122         if(NOT RUN_IN_PLACE)
 123                 set(EXAMPLE_CONF_DIR ${DOCDIR})
 124         endif()
 125         message(STATUS "Using DOCDIR=${DOCDIR}")
 126 endif()
 127
 128 set(CUSTOM_MANDIR "" CACHE STRING "Directory to install manpages into")
 129 if(NOT CUSTOM_MANDIR STREQUAL "")
 130         set(MANDIR "${CUSTOM_MANDIR}")
 131         message(STATUS "Using MANDIR=${MANDIR}")
 132 endif()
 133
 134 set(CUSTOM_EXAMPLE_CONF_DIR "" CACHE STRING "Directory to install example config file into")
 135 if(NOT CUSTOM_EXAMPLE_CONF_DIR STREQUAL "")
 136         set(EXAMPLE_CONF_DIR "${CUSTOM_EXAMPLE_CONF_DIR}")
 137         message(STATUS "Using EXAMPLE_CONF_DIR=${EXAMPLE_CONF_DIR}")
 138 endif()
 139
 140 set(CUSTOM_XDG_APPS_DIR "" CACHE STRING "Directory to install .desktop files into")
 141 if(NOT CUSTOM_XDG_APPS_DIR STREQUAL "")
 142         set(XDG_APPS_DIR "${CUSTOM_XDG_APPS_DIR}")
 143         message(STATUS "Using XDG_APPS_DIR=${XDG_APPS_DIR}")
 144 endif()
 145
 146 set(CUSTOM_ICONDIR "" CACHE STRING "Directory to install icons into")
 147 if(NOT CUSTOM_ICONDIR STREQUAL "")
 148         set(ICONDIR "${CUSTOM_ICONDIR}")
 149         message(STATUS "Using ICONDIR=${ICONDIR}")
 150 endif()
 151
 152 set(CUSTOM_LOCALEDIR "" CACHE STRING "Directory to install l10n files into")
 153 if(NOT CUSTOM_LOCALEDIR STREQUAL "")
 154         set(LOCALEDIR "${CUSTOM_LOCALEDIR}")
 155         message(STATUS "Using LOCALEDIR=${LOCALEDIR}")
 156 endif()
 157
 158
 159 install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/builtin" DESTINATION "${SHAREDIR}")
 160 if(RUN_IN_PLACE)
 161         install(FILES "${CMAKE_CURRENT_SOURCE_DIR}/mods/mods_here.txt" DESTINATION "${SHAREDIR}/mods")
 162         install(FILES "${CMAKE_CURRENT_SOURCE_DIR}/textures/texture_packs_here.txt" DESTINATION "${SHAREDIR}/textures")
 163 endif()
 164
 165 install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/games" DESTINATION "${SHAREDIR}" PATTERN ".git*" EXCLUDE)
 166
 167 if(BUILD_CLIENT)
 168         install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/client/shaders" DESTINATION "${SHAREDIR}/client")
 169         install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/textures/base/pack" DESTINATION "${SHAREDIR}/textures/base")
 170         if(RUN_IN_PLACE)
 171                 install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/clientmods" DESTINATION "${SHAREDIR}")
 172                 install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/client/serverlist" DESTINATION "${SHAREDIR}/client")
 173         endif()
 174 endif()
 175
 176 install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/fonts" DESTINATION "${SHAREDIR}")
 177
 178 install(FILES "README.md" DESTINATION "${DOCDIR}")
 179 install(FILES "LICENSE.txt" DESTINATION "${DOCDIR}")
 180 install(FILES "doc/lua_api.txt" DESTINATION "${DOCDIR}")
 181 install(FILES "doc/menu_lua_api.txt" DESTINATION "${DOCDIR}")
 182 install(FILES "doc/texture_packs.txt" DESTINATION "${DOCDIR}")
 183 install(FILES "doc/world_format.txt" DESTINATION "${DOCDIR}")
 184 install(FILES "minetest.conf.example" DESTINATION "${EXAMPLE_CONF_DIR}")
 185
 186 if(UNIX AND NOT APPLE)
 187         install(FILES "doc/minetest.6" "doc/minetestserver.6" DESTINATION "${MANDIR}/man6")
 188         install(FILES "misc/net.minetest.minetest.desktop" DESTINATION "${XDG_APPS_DIR}")
 189         install(FILES "misc/net.minetest.minetest.appdata.xml" DESTINATION "${APPDATADIR}")
 190         install(FILES "misc/minetest.svg" DESTINATION "${ICONDIR}/hicolor/scalable/apps")
 191         install(FILES "misc/minetest-xorg-icon-128.png"
 192                 DESTINATION "${ICONDIR}/hicolor/128x128/apps"
 193                 RENAME "minetest.png")
 194 endif()
 195
 196 if(APPLE)
 197         install(FILES "misc/minetest-icon.icns" DESTINATION "${SHAREDIR}")
 198         install(FILES "misc/Info.plist" DESTINATION "${BUNDLE_PATH}/Contents")
 199 endif()
 200
 201 # Library pack
 202 find_package(GMP REQUIRED)
 203 find_package(Json REQUIRED)
 204 find_package(Lua REQUIRED)
 205
 206 # Subdirectories
 207 # Be sure to add all relevant definitions above this
 208
 209 add_subdirectory(src)
 210
 211
 212 # CPack
 213
 214 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "An InfiniMiner/Minecraft inspired game")
 215 set(CPACK_PACKAGE_VERSION_MAJOR ${VERSION_MAJOR})
 216 set(CPACK_PACKAGE_VERSION_MINOR ${VERSION_MINOR})
 217 set(CPACK_PACKAGE_VERSION_PATCH ${VERSION_PATCH})
 218 set(CPACK_PACKAGE_VENDOR "celeron55")
 219 set(CPACK_PACKAGE_CONTACT "Perttu Ahola <celeron55@gmail.com>")
 220
 221 if(WIN32)
 222         if(CMAKE_SIZEOF_VOID_P EQUAL 8)
 223                 set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-win64")
 224         else()
 225                 set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-win32")
 226         endif()
 227
 228         set(CPACK_GENERATOR ZIP)
 229 elseif(APPLE)
 230         set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
 231         set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-osx")
 232         set(CPACK_GENERATOR ZIP)
 233 else()
 234         set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-linux")
 235         set(CPACK_GENERATOR TGZ)
 236         set(CPACK_SOURCE_GENERATOR TGZ)
 237 endif()
 238
 239 include(CPack)
 240
 241
 242 # Add a target to generate API documentation with Doxygen
 243 find_package(Doxygen)
 244 if(DOXYGEN_FOUND)
 245         configure_file(${CMAKE_CURRENT_SOURCE_DIR}/doc/Doxyfile.in
 246                         ${CMAKE_CURRENT_BINARY_DIR}/doc/Doxyfile @ONLY)
 247         add_custom_target(doc
 248                 ${DOXYGEN_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/doc/Doxyfile
 249                 WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/doc
 250                 COMMENT "Generating API documentation with Doxygen" VERBATIM
 251         )
 252 endif()
 253