CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2 if(${CMAKE_VERSION} STREQUAL "2.8.2")
   3   # bug http://vtk.org/Bug/view.php?id=11020
   4   message( WARNING "CMake/CPack version 2.8.2 will not create working .deb packages!")
   5 endif(${CMAKE_VERSION} STREQUAL "2.8.2")
   6
   7 # This can be read from ${PROJECT_NAME} after project() is called
   8 project(minetest)
   9
  10 # Also remember to set PROTOCOL_VERSION in clientserver.h when releasing
  11 set(VERSION_MAJOR 0)
  12 set(VERSION_MINOR 4)
  13 set(VERSION_PATCH dev-20120311)
  14 set(VERSION_STRING "${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH}")
  15
  16 MESSAGE(STATUS "*** Will build version ${VERSION_STRING} ***")
  17
  18 # Configuration options
  19
  20 if(WIN32)
  21         set(RUN_IN_PLACE 1 CACHE BOOL "Run directly in source directory structure")
  22 else()
  23         set(RUN_IN_PLACE 0 CACHE BOOL "Run directly in source directory structure")
  24 endif()
  25
  26 set(BUILD_CLIENT 1 CACHE BOOL "Build client")
  27 if(WIN32)
  28         set(BUILD_SERVER 0 CACHE BOOL "Build server")
  29 else()
  30         set(BUILD_SERVER 1 CACHE BOOL "Build server")
  31 endif()
  32
  33 set(WARN_ALL 1 CACHE BOOL "Enable -Wall for Release build")
  34
  35 if(NOT CMAKE_BUILD_TYPE)
  36         # Default to release
  37         set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type: Debug or Release" FORCE)
  38 endif()
  39
  40 # Included stuff
  41 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_SOURCE_DIR}/cmake/Modules/")
  42 include(${CMAKE_SOURCE_DIR}/cmake/Modules/misc.cmake)
  43
  44 # This is done here so that relative search paths are more reasnable
  45 find_package(Irrlicht)
  46
  47 #
  48 # Installation
  49 #
  50
  51 if(WIN32)
  52         set(SHAREDIR "share")
  53         set(BINDIR "bin")
  54         set(DOCDIR "doc")
  55         set(EXAMPLE_CONF_DIR "user")
  56 elseif(APPLE)
  57         # random placeholders
  58         set(SHAREDIR "share/${PROJECT_NAME}")
  59         set(BINDIR "bin")
  60         set(DOCDIR "share/doc/${PROJECT_NAME}")
  61         set(EXAMPLE_CONF_DIR ${DOCDIR})
  62 elseif(UNIX) # Linux, BSD etc
  63         if(RUN_IN_PLACE)
  64                 set(SHAREDIR "share")
  65                 set(BINDIR "bin")
  66                 set(DOCDIR "doc")
  67                 set(MANDIR "share/unix/man")
  68                 set(EXAMPLE_CONF_DIR ${DOCDIR})
  69                 set(XDG_APPS_DIR "share/unix/applications")
  70                 set(ICONDIR "share/unix/icons")
  71         else()
  72                 set(SHAREDIR "share/${PROJECT_NAME}")
  73                 set(BINDIR "bin")
  74                 set(DOCDIR "share/doc/${PROJECT_NAME}")
  75                 set(MANDIR "share/man")
  76                 set(EXAMPLE_CONF_DIR ${DOCDIR})
  77                 set(XDG_APPS_DIR "share/applications")
  78                 set(ICONDIR "share/icons")
  79         endif()
  80 endif()
  81
  82 install(FILES "README.txt" DESTINATION "${DOCDIR}")
  83 install(FILES "minetest.conf.example" DESTINATION "${EXAMPLE_CONF_DIR}")
  84
  85 if(UNIX)
  86         install(FILES "doc/minetest.6" "doc/minetestserver.6" DESTINATION "${MANDIR}/man6")
  87         install(FILES "misc/minetest.desktop" DESTINATION "${XDG_APPS_DIR}")
  88         install(FILES "minetest-icon.svg" DESTINATION "${ICONDIR}/hicolor/scalable/apps")
  89 endif()
  90
  91 #
  92 # Subdirectories
  93 # Be sure to add all relevant definitions above this
  94 #
  95
  96 add_subdirectory(src)
  97
  98 # CPack
  99
 100 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "An InfiniMiner/Minecraft inspired game")
 101 set(CPACK_PACKAGE_VERSION_MAJOR ${VERSION_MAJOR})
 102 set(CPACK_PACKAGE_VERSION_MINOR ${VERSION_MINOR})
 103 set(CPACK_PACKAGE_VERSION_PATCH ${VERSION_PATCH})
 104 set(CPACK_PACKAGE_VENDOR "celeron55")
 105 set(CPACK_PACKAGE_CONTACT "Perttu Ahola <celeron55@gmail.com>")
 106
 107 if(WIN32)
 108         # For some reason these aren't copied otherwise
 109         # NOTE: For some reason now it seems to work without these
 110         #if(BUILD_CLIENT)
 111         #       install(FILES bin/minetest.exe DESTINATION bin)
 112         #endif()
 113         #if(BUILD_SERVER)
 114         #       install(FILES bin/minetestserver.exe DESTINATION bin)
 115         #endif()
 116
 117         set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-win32")
 118
 119         set(CPACK_GENERATOR ZIP)
 120
 121         # This might be needed for some installer
 122         #set(CPACK_PACKAGE_EXECUTABLES bin/minetest.exe "Minetest" bin/minetestserver.exe "Minetest Server")
 123 elseif(APPLE)
 124         # TODO
 125         # see http://cmake.org/Wiki/CMake:CPackPackageGenerators#Bundle_.28OSX_only.29
 126         #
 127         set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-osx")
 128         set(CPACK_PACKAGE_ICON "")
 129         set(CPACK_BUNDLE_NAME ${PROJECT_NAME})
 130         set(CPACK_BUNDLE_ICON "")
 131         set(CPACK_BUNDLE_PLIST "")
 132         set(CPACK_BUNDLE_STARTUP_COMMAND "Contents/MacOS/${PROJECT_NAME}")
 133         set(CPACK_GENERATOR "Bundle")
 134 else()
 135         set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-linux")
 136         set(CPACK_GENERATOR TGZ)
 137         set(CPACK_SOURCE_GENERATOR TGZ)
 138 endif()
 139
 140 include(CPack)
 141